O lote exporta vídeos selecionados com o QuickTime Player 7 usando configurações de exportação específicas?

Question

Como eu posso usar o applescript ou o Automator para exportar arquivos de vídeo que eu selecionei no Finder, mas NÃO usando o método de serviço "Encode Selected Video Files", só tem 4 formatos para escolher?

Basicamente, preciso exportar os vídeos usando as "Configurações mais recentes" escolhidas na última vez em que exportei um vídeo do QuickTime 7 ou para ter uma opção de especificar as configurações usando a caixa de diálogo de exportação do QuickTime 7 para escolher formatação específica que eu preciso para os vídeos que eu selecionei.

Às vezes, eu preciso que o codec seja "Apple ProRes 422 LT", e outras vezes eu preciso usar o "Apple ProRes 422" regular. Também precisarei garantir que a taxa de quadros esteja configurada para 30, independentemente da taxa de quadros do arquivo de origem, e as dimensões serão 1280x720 ou 1920x1080.

Por fim, também precisarei definir opções diferentes para a codificação de áudio para diferentes vídeos.

Espero que alguém saiba uma maneira de fazer isso. Eu tenho cavado por aqui e no Google e não consegui descobrir. Parece que a maioria das informações que estou encontrando on-line é apenas dizer às pessoas como usar o mesmo método, que está usando o serviço "Codificar arquivos de vídeo selecionados".

    

Answer 1

Eureka! Eu encontrei um fluxo de trabalho do Automator online que realmente funciona. Eu apenas tive que modificá-lo para ter arquivos de filme como entrada em vez de imagens. Ele usa as "Configurações mais recentes" no QuickTime 7, então eu só preciso exportar o primeiro vídeo manualmente para obter as configurações digitadas corretamente, e o resto eu posso apenas selecionar e agrupar. Viva!

A página original que encontrei com o arquivo de informações e fluxo de trabalho está aqui: link

Eu adicionarei o script aqui também, caso a página que eu vincule desapareça. Isso só precisa ser adicionado no Automator como um serviço, com arquivos de filme do Finder como entrada.

EaquiestáoAppleScriptparaadicionaraoserviço.Acabeidesalvaroserviçocomo"Export_mov_via_QuickTime7.workflow".

on run {inputFiles}
    if inputFiles is equal to {} then
        set inputFiles to (choose file with prompt "Select the file(s) to convert:" with multiple selections allowed without invisibles)
    end if
    open inputFiles
end run

on open droppedItems
    tell application "Finder" to set inputFolder to (container of first item of droppedItems) as Unicode text
    set outputFolder to (choose folder with prompt "Select output folder:" default location (inputFolder as alias)) as Unicode text

    display dialog "Most recent QuickTime 7 export settings will be used.
Existing files will be overwritten/moved to trash!
Beware of evil QT7 Gamma shift!"

    tell application "QuickTime Player 7"
        activate
        close every window
    end tell

    repeat with currentItem in droppedItems
        tell application "Finder" to set fileName to name of currentItem as Unicode text

        tell application "QuickTime Player 7"
            open currentItem
            tell front document to set frameCount to count of frames of first track
        end tell

        set outputFileName to (outputFolder & fileName & ".mov")

        tell application "Finder"
            if exists file outputFileName then
                delete file outputFileName
            end if
        end tell

        tell application "QuickTime Player 7"
            if frameCount is greater than 1 then
                with timeout of 86400 seconds -- 24 hours
                    export front document to outputFileName as QuickTime movie using most recent settings
                end timeout
            end if
            close front document
        end tell
    end repeat

    quit application "QuickTime Player 7"
end open

Agora, sempre que você quiser exportar vídeos em lote usando o QuickTime Player 7 Pro com as configurações escolhidas, basta selecionar todos os outros vídeos que deseja exportar, selecionar o serviço no menu "Localizar e> Serviços" e aproveite um bom café enquanto todos os seus vídeos são convertidos! = D