Fórmula do Excel para preenchimento automático de uma data

Question

Eu gostaria que as células F4-F23 preenchessem automaticamente a data de hoje sempre que os dados fossem inseridos nas células E4-E23. Em seguida, preciso ter preenchimento automático de células I4-I23 com a data de hoje, sempre que os dados forem inseridos nas células H4-H23. Os dados introduzidos nas células H4-H23 serão introduzidos em dias diferentes dos dados introduzidos nas células E4-E23. Eu encontrei este código que funciona para a primeira parte da minha pergunta, eu preciso saber como modificá-lo para trabalhar nas células H e eu.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim E As Range, F As Range, Inte As Range, r As Range
    Set E = Range("E:E")
    Set Inte = Intersect(E, Target)
    If Inte Is Nothing Then Exit Sub
    Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
    Application.EnableEvents = True
End Sub

    

Answer 1

Tente isto:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim E As Range, H As Range, Inte As Range, r As Range
    Set E = Range("E:E")
    Set H = Range("H:H")
    Set Inte = Intersect(E, Target)
    If Not Inte Is Nothing Then
        Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
        Application.EnableEvents = True
    End If
    Set Inte = Intersect(H, Target)
    If Not Inte Is Nothing Then
        Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
        Application.EnableEvents = True
    End If
End Sub

Em vez de sair do sub quando a interseção é nada, verifique o oposto de nothing e execute o código em cada interseção separadamente.

Note que eu declarei H como intervalo e removi a declaração não utilizada de F como intervalo.