Como posso usar a fórmula INDEX MATCH com dois parâmetros horizontais?

Question

Não tenho certeza se alguém pode me ajudar, mas pensei em dar uma chance ...

Estou tentando criar uma fórmula para recuperar informações de uma folha de dados. A planilha de dados contém uma quantidade significativa de informações, dividindo os dados com base no local da loja, na localização do cliente e no tipo de informação (informações de receita, GP1, GP2).

Gostaria que uma fórmula fosse dinâmica para que, quando for copiada em minha planilha de resumo, ela analise automaticamente o local da loja, o local do cliente e o tipo de informação aplicáveis e recupere-a de acordo. No momento, configurei a fórmula como

=INDEX('[Profitability Analysis FY13.xlsx]Data Sheet S13'!$B$8:$EH$85,MATCH($A17,('[ Profitability Analysis FY13.xlsx] Data Sheet S13'!$E$8:$E$85),0),MATCH(1,$B17=' Profitability Analysis FY13.xlsx] Data Sheet S13'!$B$4:$EH$4)*(J14='[Profitability Analysis FY13.xlsx] Data Sheet S13'!$B$7:$EH$7),0)

A ideia é que a fórmula observe as células em B8 - EH85 na planilha de dados e recupere as informações com base no valor de pesquisa vertical (local da loja) especificado na célula A17 e a pesquisa horizontal valor com base na localização do cliente (célula B17) e tipo de informação (célula J14) estão alinhados.

O problema com essa fórmula parece estar no aspecto de vários critérios (a pesquisa horizontal). Alguém tem alguma sugestão de como eu posso reformular a fórmula para que ela funcione corretamente?

    

Answer 1

Sua fórmula parece boa para mim, exceto por alguns problemas com parênteses, tente esta versão

=INDEX('[Profitability Analysis FY13.xlsx]Data Sheet S13'!$B$8:$EH$85,MATCH($A17,'[ Profitability Analysis FY13.xlsx] Data Sheet S13'!$E$8:$E$85,0),MATCH(1,($B17=' Profitability Analysis FY13.xlsx] Data Sheet S13'!$B$4:$EH$4)*(J14='[Profitability Analysis FY13.xlsx] Data Sheet S13'!$B$7:$EH$7),0))

Ele precisa ser confirmado com CTRL + SHIFT + ENTER

Por simplicidade, o formulário genérico é

=INDEX(Matrix,MATCH("x",row_labels,0),MATCH(1,("y"=headers1)*("z"=headers2),0))

que é o que você tem acima

.... ou você pode adicionar outra função INDEX para evitar "entrada de matriz", ou seja, na versão genérica:

=INDEX(Matrix,MATCH("x",row_labels,0),MATCH(1,INDEX(("y"=headers1)*("z"=headers2),0),0))