Adicione um botão do painel de navegação a todos os tipos de pasta
O procedimento a seguir adicionará uma maneira rápida de alternar o painel de navegação, bem ao lado do botão Organizar .
Etapas preliminares
-
Faça logon com uma conta de administrador.
-
Pressione Win + R , digite ou cole
regedit.exena caixa de texto e pressione Enter . -
Navegue até a chave de registro
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CommandStore\shell\Windows.navpane. -
Clique com o botão direito do mouse na chave do Registro e selecione Permissões no menu de contexto.
-
Clique no botão Avançado e clique na guia Proprietário . Ative a opção Substituir proprietário em subcontainers e objeto , selecione o grupo Administradores na lista e clique em OK .
-
Selecione o grupo Administradores na lista Segurança e ative a caixa de seleção Permitir para o Controle total opção. Aplique as alterações e clique em OK .
-
Clique com o botão direito em uma área vazia no painel direito e escolha Novo > Valor da string no menu. Nomeie o novo valor como
Positione defina comoAfter. -
Crie um novo valor de string chamado
PositionComparee defina como{7ddc1264-7e4d-4f74-bbc0-d191987c8d0f}. -
Repita as etapas 3 a 6 para as seguintes chaves do Registro:
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes\{5c4f28b5-f869-4e84-8e60-f11db97c5cc7} HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes\{5fa96407-7e77-483c-ac93-691d05850de8} HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes\{7d49d726-3c21-4f05-99aa-fdc2c9474656} HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes\{94d6ddcc-4a68-4175-a374-bd584a510b78} HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes\{b3690e58-e961-423b-b687-386ebfd83239}
Automatização em lote
Existem muitos tipos de pasta, e fazer as alterações necessárias à mão seria annyoing. Salve o código a seguir como AddNavPaneButton.cmd (ou qualquer outro, desde que ele tenha a extensão .cmd) e execute-o como administrador.
@echo off
setlocal enabledelayedexpansion
pushd "%~dp0"
REM Contacts.Library, Contacts.LibraryFolder
REM Contacts.SearchResults, Documents
REM Documents.Library, Documents.LibraryFolder
REM Documents.SearchResults, Generic
REM Generic.Library, Generic.LibraryFolder
REM Generic.SearchResults, Music
REM Music.Library, Music.LibraryFolder
REM Music.SearchResults, OpenSearch
REM OtherUsers, OtherUsers.SearchResults
REM Pictures, Pictures.Library
REM Pictures.LibraryFolder, Pictures.SearchResults
REM PublishedItems, PublishedItems.SearchResults
REM Searches, UserFiles
REM UserFiles.SearchResults, UsersLibraries
REM UsersLibraries.SearchResults, Videos
REM Videos.Library, Videos.LibraryFolder
REM Videos.SearchResults
set key=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderTypes
set subkeys=^
{524ddb2b-2a4f-43b8-b8fe-e91ef9d8ba69},{654a1b99-8a4b-4e7b-a4e1-46378ad77a61},^
{20338b7b-531c-4aad-8011-f5b3db2123ec},{7d49d726-3c21-4f05-99aa-fdc2c9474656},^
{fbb3477e-c9e4-4b3b-a2ba-d3f5d3cd46f9},{3f98a740-839c-4af7-8c36-5badfb33d5fd},^
{36011842-dccc-40fe-aa3d-6177ea401788},{5c4f28b5-f869-4e84-8e60-f11db97c5cc7},^
{5f4eab9a-6833-4f61-899d-31cf46979d49},{da3f6866-35fe-4229-821a-26553a67fc18},^
{7fde1a1e-8b31-49a5-93b8-6be14cfa4943},{94d6ddcc-4a68-4175-a374-bd584a510b78},^
{3f2a72a7-99fa-4ddb-a5a8-c604edf61d6b},{978e0ed7-92d6-4cec-9b59-3135b9c49ccf},^
{71689ac1-cc88-45d0-8a22-2943c3e7dfb3},{8faf9629-1980-46ff-8023-9dceab9c3ee3},^
{B337FD00-9DD5-4635-A6D4-DA33FD102B7A},{3D1D4EA2-1D8C-418a-BFF8-F18370157B55},^
{b3690e58-e961-423b-b687-386ebfd83239},{0b2baaeb-0042-4dca-aa4d-3ee8648d03e5},^
{c1f8339f-f312-4c97-b1c6-ecdf5910c5c0},{4dcafe13-e6a7-4c28-be02-ca8c2126280d},^
{7F2F5B96-FF74-41da-AFD8-1C78A5F3AEA2},{921C636D-9FC8-40d7-899E-0845DCD03010},^
{0b0ba2e3-405f-415e-a6ee-cad625207853},{CD0FC69B-71E2-46e5-9690-5BCD9F57AAB3},^
{e053a11a-dced-4515-8c4e-d51ba917517b},{C4D98F09-6124-4fe0-9942-826416082DA9},^
{59BD6DD1-5CEC-4d7e-9AD2-ECC64154418D},{5fa96407-7e77-483c-ac93-691d05850de8},^
{631958a6-ad0f-4035-a745-28ac066dc6ed},{292108be-88ab-4f33-9a26-7748e62e37ad},^
{ea25fbd7-3bf7-409e-b97f-3352240903f4}
for %%A in (%subkeys%) do (
set value1=
set value2=
for /f "tokens=3" %%B in ('"reg query "%key%\%%A" /ve /f "TasksItemsSelected" /k /s 2>&1 | findstr /c:"REG_SZ" "') do set value1=%%B
for /f "tokens=3" %%C in ('"reg query "%key%\%%A" /ve /f "TasksNoItemsSelected" /k /s 2>&1 | findstr /c:"REG_SZ" "') do set value2=%%C
if defined value2 (
echo !value1!|findstr /c:"Windows.navpane" >nul
if !errorlevel! == 1 (set value1=Windows.navpane;!value1!)
echo !value2!|findstr /c:"Windows.navpane" >nul
if !errorlevel! == 1 (set value2=Windows.navpane;!value2!)
) else (
set value1=Windows.navpane
set value2=Windows.navpane
)
reg add "%key%\%%A\TasksItemsSelected" /ve /t REG_SZ /d !value1! /f >nul
reg add "%key%\%%A\TasksNoItemsSelected" /ve /t REG_SZ /d !value2! /f >nul
)
popd
pause & exit /b
