Macro - linha Localizar trabalho, copiar e colar

Question

Eu gostaria de criar uma macro para encontrar um trabalho (use a função find) e depois copiar a linha em que o trabalho está e copiar e colar toda a linha, incluindo valores e fórmulas.

O número do trabalho a ser encontrado irá variar a cada vez, portanto, gostaria que aparecesse uma caixa pop-up que eu possa preencher e falhará se nenhuma correspondência ocorrer.

Alguém pode ajudar?

    

Answer 1

Aqui está uma macro VBA de exemplo para você começar. Comentários no código para descrever a intenção. Você pode querer adicionar tratamento de erros para atender às suas necessidades.

Sub CopyData()
    Dim res As String
    Dim cl As Range
    Dim sh As Worksheet

    ' operate on the active sheet
    Set sh = ActiveSheet

    ' ask for ID to find in column A
    res = InputBox("Enter ID to Find", "Copy Row")

    ' If no responce, exit
    If res = "" Then
        Exit Sub
    End If

    With sh
        ' Find first occurance
        Application.FindFormat.Clear
        Set cl = .Columns(1).Find(What:=res, _
            After:=.Cells(.Rows.Count, 1), _
            LookIn:=xlValues, _
            LookAt:=xlWhole, _
            SearchOrder:=xlByRows, _
            SearchDirection:=xlNext, _
            MatchCase:=True)

        If Not cl Is Nothing Then
            ' if found, select entire row
            Set cl = cl.EntireRow
            ' copy and insert paste data into next row
            cl.Copy
            cl.Offset(1, 0).Insert
            ' turn off copy highlight (moving border)
            Application.CutCopyMode = False
        End If
    End With
End Sub