Como posso fazer com que o Word 2007/2010 envie seu conteúdo por e-mail, com minha assinatura?

Question

Os usuários têm a obrigação de enviar documentos em Word no corpo de um email (não como anexo) e incluir uma assinatura em todas as correspondências por email.

No momento, os usuários estão usando Send to Mail Recipient , que insere o documento no corpo de um e-mail, mas não podem adicionar automaticamente sua assinatura e devem adicioná-lo manualmente a cada e-mail. Pelo que entendi, isso acontece porque a correspondência incorporada no Word não é igual à versão completa do Outlook.

O comando regular E-Mail no Word exibirá uma nova mensagem de email com sua assinatura, no entanto, o documento é um anexo, e não no corpo do email.

Existe uma maneira de o Word enviar seu conteúdo ao corpo de um email e inserir automaticamente a assinatura do usuário?

Estou procurando uma solução que funcione tanto no Office 2007 quanto no 2010 e que as macros estejam OK.

    

Answer 1

Encontrei uma macro do Word para ativar essa funcionalidade no HowTo-Outlook.com, em " Enviar documento do Word como e-mail ":

Sub SendDocAsMail()

Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

'Start Outlook if it isn't running
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
    Set oOutlookApp = CreateObject("Outlook.Application")
End If

'Create a new message
Set oItem = oOutlookApp.CreateItem(olMailItem)

'Allow the user to write a short intro and put it at the top of the body
Dim msgIntro As String
msgIntro = InputBox("Write a short intro to put above your default " & _
            "signature and current document." & vbCrLf & vbCrLf & _
            "Press Cancel to create the mail without intro and " & _
            "signature.", "Intro")

'Copy the open document
Selection.WholeStory
Selection.Copy
Selection.End = True

'Set the WordEditor
Dim objInsp As Outlook.Inspector
Dim wdEditor As Word.Document
Set objInsp = oItem.GetInspector
Set wdEditor = objInsp.WordEditor

'Write the intro if specified
Dim i As Integer
If msgIntro = IsNothing Then
    i = 1
    'Comment the next line to leave your default signature below the document
    wdEditor.Content.Delete
Else
    'Write the intro above the signature
    wdEditor.Characters(1).InsertBefore (msgIntro)
    i = wdEditor.Characters.Count
    wdEditor.Characters(i).InlineShapes.AddHorizontalLineStandard
    wdEditor.Characters(i + 1).InsertParagraph
    i = i + 2
End If

'Place the current document under the intro and signature
wdEditor.Characters(i).PasteAndFormat (wdFormatOriginalFormatting)

'Display the message
oItem.Display

'Clean up
Set oItem = Nothing
Set oOutlookApp = Nothing
Set objInsp = Nothing
Set wdEditor = Nothing

End Sub

Se você precisar de ajuda passo-a-passo para obter a macro no Word, o link real (acima) terá isso, incluindo imagens.