Incluindo o título do slide no folheto do Notes automaticamente (PowerPoint 2016)

Question

Eu quero criar um manual a partir de uma apresentação do PowerPoint, onde as informações na seção Anotações fazem parte da impressão. Para que eu possa formatar os títulos dos slides para fazer parte de um sumário, quero que o título do slide esteja em texto, não apenas parte da imagem do slide.

Como opções de exportação, posso escolher Notas abaixo dos slides (mas o título do slide não está no formato de texto) ou posso imprimir apenas o Esboço (mas notas de slides não estão incluídas.)

No Notes Master, vejo uma caixa Cabeçalho e tentei colocar um título de slide lá, mas parece não haver uma maneira de especificar o título do slide para cada slide automaticamente. ou seja, não posso incluir uma variável para o título na caixa Cabeçalho.

Se eu olhar na vista de destaques, não vejo o texto das notas.

Existe uma maneira de criar automaticamente um folheto que inclua as informações da Estrutura de tópicos e o texto das notas?

    

Answer 1

Isso selecionará o texto do título de cada slide e o adicionará à página de anotações. Modifique conforme necessário para alterar a formatação / posição do texto.

Sub AddTitlesToNotesPages()

    Dim oSld As Slide
    Dim oShp As Shape
    Dim sTitleText As String

    For Each oSld In ActivePresentation.Slides

        ' get the slide's title text
        sTitleText = GetTitleText(oSld)

        ' add a text shape with the text to notes page
        ' placement is totally arbitrary; edit to suit
        Set oShp = oSld.NotesPage.Shapes.AddTextbox(msoTextOrientationHorizontal, _
                   0, 0, 500, 100)
        With oShp.TextFrame.TextRange
            .Text = sTitleText
            ' modify other stuff as needed
            .Font.Name = "Arial"
            .Font.Color.RGB = RGB(0, 0, 0)  ' black
            ' and so on
        End With
    Next     ' Slide

End Sub

Function GetTitleText(oSld As Slide) As String
' Returns the title text for oSld if any, or "Slide xxx" if not
    Dim oShp As Shape
    Dim sTemp As String
    For Each oShp In oSld.Shapes
        If oShp.Type = msoPlaceholder Then
            If oShp.PlaceholderFormat.Type = ppPlaceholderCenterTitle Or oShp.PlaceholderFormat.Type = ppPlaceholderTitle Then
                sTemp = oShp.TextFrame.TextRange.Text
            End If
        End If
    Next

    ' if we got this far and didn't find a slide title:
    If Len(sTemp) = 0 Then
        ' return the slide index number
        GetTitleText = "Slide " & CStr(oSld.SlideIndex)
    Else
        ' return the title
        GetTitleText = sTemp
    End If

End Function