Editando uma fórmula existente para adicionar várias fórmulas IF e outros requisitos

Question

Estou usando uma fórmula para contabilidade para calcular as vendas em um grupo de estados que se parece com isso:

=IF(COUNTIF(G2150,"MA")+COUNTIF(G2150,"CT")+COUNTIF(G2150,"RI"),IF(EXACT(L2150,"Apple"),(N2150*2),(N2150*4)),"")

Esta fórmula funciona atualmente, no entanto, gostaria de adicioná-la e não consegui descobrir.

Atualmente, funciona como:

• Se a coluna de estado G for MA , RI ou CT e se a coluna do produto L for Apple , você multiplica a coluna de quantidade por 2.
• Se não for Apple , você multiplique por 4.
• Se não estiver nesses estados, deixe em branco.

Esta fórmula funciona muito bem se houver apenas dois produtos envolvidos.

Estamos adicionando um novo inventário com preços diferentes. Eu preciso alterá-lo para algo que funciona assim:

• Se a coluna de estado G for X , Y ou Z e se a coluna do produto L for Apple , multiplique a coluna de quantidade N por 4.
• Se o produto nesses mesmos estados for Orange na coluna L , multiplique por 2.
• Se o produto de uma coluna diferente K nesses mesmos estados for Pineapple , multiplique a quantidade N por 3.
• Qualquer coisa que não esteja nesses estados, deixe em branco. E assim por diante.

Isso é possível?

Eu tenho três produtos / três preços da coluna K para adicionar, além de dois produtos da coluna L . Todas as quantidades estão na coluna N .

    

Answer 1

Use OU com uma matriz para os estados:

OR(G2150={"MA","CT","RI"})

Em seguida, use alguns booleanos para retornar o multiplicador correto.

((L2150="Apple")*4)+((L2150="Orange")*2)+((K2150="Pineapple")*3)

Então:

=IF(OR(G2150={"MA","CT","RI"}),(((L2150="Apple")*4)+((L2150="Orange")*2)+((K2150="Pineapple")*3))*N2150,"")