O atalho do Windows Explorer para ir para a pasta do próximo irmão?

Question

Estou procurando um atalho de tecla no Windows 10 que me permita navegar da pasta A para a pasta B de dentro da pasta A:

- Top Folder
-- A (I am here)
-- B

Atalho e, em seguida:

- Top Folder
-- A 
-- B (now I am here)

Não foi possível encontrar informações sobre um atalho nativo para isso.

PS: Um script AHK também seria útil.

    

Answer 1

Trabalhou com este ótimo script Autohotkey:

; navigate to next sibling folder from Windows Explorer
#If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass")
^PgUp::
^PgDn:: NavigateToSiblingDir( InStr(A_ThisHotkey, "Up") )

NavigateToSiblingDir(UpDown)  {
   oShell := ComObjCreate("Shell.Application")
   WinGet, hWnd,, A
   for oWin in oShell.Windows  {
      if (hWnd = oWin.hwnd)  {
         oFolder := oWin.Document.Folder
         startDirPath  := oFolder.Self.Path
         parentDirPath := oFolder.ParentFolder.Self.Path
         break
      }
   }

   for item in oShell.Namespace(parentDirPath).Items  {
      if !item.IsFolder
         continue
      if (found && nextSiblingPath := item.Path)
         break
      if (item.Path = startDirPath && found := true)
         prevSiblingPath := prev
      prev := item.Path
   }

   if (UpDown && prevSiblingPath)
      oWin.Navigate(prevSiblingPath)
   if (!UpDown && nextSiblingPath)
      oWin.Navigate(nextSiblingPath)
}

Github: explorer-navigate-sibling-folder.ahk

Meus sinceros agradecimentos e créditos vão para teadrinker & jeeswg (AHK) .