adicionando células com datas

Question

Estou tentando somar um intervalo total de células entre os períodos ou seja, a coluna n tem $ montantes    a coluna d tem as datas da transação, por exemplo, 1/3/2015 ou 25/3/2015 ou 25/4/2015    coluna b tem o texto dizendo drp ou distribuição - reinv

Em outra célula, estou tentando somar ou totalizar (na coluna n) o valor de um intervalo de datas diferentes (coluna d) que contêm texto diferente (coluna b)     ou seja, a célula n48 é 50, n65 é 85, n165 é 36

com as datas     ou seja, célula d48 é 1/3/2015, d65 é 25/3/2015 e d165 é 25/4/2015

com texto diferente que diz drp ou distribuição - reinv     ou seja, a célula b48 é drp, b65 é a distribuição - reinv, b165 é drp

Se eu quisesse somar os valores entre 1/3/2015 a 31/3/2015 com drp, o total seria 50. Além disso, se eu quisesse somar os valores entre 1/4/2015 a 30/4/2015 com drp, o total seria 36 Se eu quisesse somar os valores entre 1/3/2015 e 31/3/2015 com drp e distribuição - reinv a soma seria 115

Qual seria a fórmula para essas diferentes perguntas

espero que você possa ajudar, isso tem me deixado maluco e não consigo resolvê-lo

    

Answer 1

Como Michthan disse, uma tabela dinâmica pode fazer isso, mas pode ser assustadora para alguém que nunca trabalhou com eles antes. No entanto, a função SUMIFS () é exatamente o que você precisa neste caso:

Cenário 1:

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31))

Cenário 2:

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,4,1),$D:$D,"<="&DATE(2015,4,30))

Cenário 3:

=SUM(SUMIFS($N:$N,$B:$B,{"drp","distribution - reinv"},$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31)))

Embora funcionem exatamente para as condições que você declarou (e você pode editar as datas nas fórmulas da maneira que preferir), elas não são muito flexíveis no caso de você querer alterar seus critérios. Seria melhor manter seus critérios em algumas células como $ O $ 1: $ O $ 4 e se referir a essas células na fórmula da seguinte forma:

$O$1 = drp [text]
$O$2 = 1/3/2015 [start date]
$O$3 = 31/3/2015 [end date]

E a fórmula se tornaria

=SUMIFS($N:$N,$B:$B,$O$1,$D:$D,">="&$O$2,$D:$D,"<="&$O$3)

Observação: não consegui obter vários critérios de texto OR () com referências de célula para funcionar, mesmo em uma função INDIRECT (). Se alguém puder fornecer orientação adicional, tenho certeza que Murray apreciaria isso.