Mesclar dados de muitos arquivos do Excel em um único arquivo do Excel [fechado]

Question

Eu preciso mesclar dados de mais de 100 arquivos do Excel em um único arquivo usando o VBA, onde:

meu repositório (D: \ rep) contém mais de 100 arquivos com nome de (arquivo1, arquivo2 ... etc) todos os arquivos do Excel consistem em 18 linhas corrigidas em todos os arquivos do Excel e com diferentes números de colunas, seguindo a amostra dos meus arquivos do Excel

exemplo de arquivos do Excel

Eu preciso mesclar os dados de todos os arquivos em um arquivo e combinar os dados da seguinte forma:

as linhas ainda são as mesmas no novo arquivo, coluna 1 é a coluna (arquivo 1) e seu valor se refere à soma dos valores das linhas, conforme mostrado na figura a seguir

exemplo de arquivo mesclado

    

Answer 1

Existe um método muito mais fácil e melhor que o VBA se a versão do Excel 2010 contiver a opção correta ...

Eu não usei isso com o Excel 2010, mas o PowerQuery deve estar disponível como um suplemento gratuito da Microsoft. Se a versão do addin de 2010 for parecida com a versão atual do PowerQuery, você poderá criar facilmente uma consulta que carregue todos ou alguns arquivos de uma pasta e mescle-os.

O PowerQuery é um ponto e clica na ferramenta ETL (Extrair, Transformar e Carregar) para o Excel e é (razoavelmente) fácil de usar e extremamente poderoso.

Fazer isso no VBA é muito mais complexo.

No entanto, a Microsoft fornece alguns códigos de exemplo que podem ser usados como ponto de partida

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range

    ' Create a new workbook and set a variable to the first sheet. 
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Users\Peter\invoices\"

    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1

    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")

    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)

        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName

        ' Set the source range to be A9 through C9.
        ' Modify this range for your workbooks. 
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")

        ' Set the destination range to start at column B and 
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)

        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value

        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count

        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False

        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop

    ' Call AutoFit on the destination sheet so that all 
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub

Consulte aqui para obter informações completas.

Existe também um exemplo na Stack:

link