Como instalar em lote setup-file (* .exe) no PC?

Question

Em vez de clicar duas vezes repetidamente em dezenas de arquivos de instalação (* .exe), é possível instalar em lote de uma só vez? Ou pelo menos um clique duplo é suficiente para ativá-los sequencialmente?

As soluções mais próximas do Google seriam Ninite e Instalação de velocidade . No entanto, ambos oferecem apenas opções de alguns programas predefinidos e conhecidos, não personalizáveis o suficiente para incluir alguns dos meus arquivos armazenados (* .exe).

Considerando o previsível procedimento repetitivo no futuro, poderia haver uma maneira de contornar isso?

    

Answer 1

Os instaladores comuns têm opções para "instalação silenciosa". Por exemplo, o Innosetup tem a opção de linha de comando /VERYSILENT /SUPPRESSMSGBOXES /NORESTART /DIR="C:\INSTALL\PATH" para essa finalidade, enquanto os instaladores do NSIS têm /S /D=C:\Install Path\No Quotes Allowed Even If Space Present .

Veja Instalação não supervisionada para obter mais informações.

Naturalmente, as instalações silenciosas oferecem poucas opções, por exemplo você não pode decidir se instala um pacote R de 32 ou 64 bits, mas para instalar ambos.

Como exemplo, abaixo está um arquivo em lote que criei para instalar automaticamente o TeXmacs e o maxima no sistema multimídia da minha sala de aula. As duas sub-rotinas podem ser úteis.

setlocal

set "main_dir=%USERPROFILE%\DESKTOP"
set "TeXMacs_dir=%main_dir%\mathsofts\TeXMacs"
set "maxima_dir=%main_dir%\mathsofts\maxima"

call :silent_install_inno "%~dp0TeXmacs.exe" "%TeXMacs_dir%"
call :silent_install_nsis "%~dp0maxima.exe" "%maxima_dir%"

endlocal
exit /b

:silent_install_inno
:: parameters: %1--path to the installer executable
::             %2--installation path
start "" /wait %1 /VERYSILENT /SUPPRESSMSGBOXES /NORESTART /DIR=%2
exit /b

:silent_install_nsis
:: parameters: %1--path to the installer executable
::             %2--installation path
:: note: NO QUOTES in %2 is allowed, so %~2 should be used to de-quote
start "" /wait %1 /S /D=%~2
exit /b