Script para salvar o site (pin) na barra de tarefas

Question

Eu estou procurando freneticamente por algumas referências que podem me ajudar a salvar um atalho para uma página da web (digamos msn.com) para a barra de tarefas. Eu pesquisei nos últimos quatro dias e encontrei apenas referências sobre como salvar atalhos para aplicativos (notepad.exe ou Iexplorer.exe).

Pelo que entendi, salvar qualquer página da Web inclui duas etapas

1. Criando atalho
2. Salvando o atalho (.lnk) na barra de tarefas.

Mas como posso salvar um atalho para um arquivo específico (readme.txt / msn.com) na barra de tarefas? Se você tem alguma idéia, por favor, compartilhe comigo.

    

Answer 1

LEMBRE-SE - o Windows foi projetado para impedir que os usuários sobrecarreguem os programas. Barra de tarefas e menu inicial são os usuários.

Este script lista e executa verbos em um objeto shell (somente arquivos nesta versão). Corra sem parâmetros para obter ajuda (ou leia as três primeiras linhas).

Eu chamo de ShVerb.vbs - você pode adaptá-lo para o r / c um atalho e escolher Adicionar à barra de tarefas (talvez - eu tenho o Vista o último dos sistemas operacionais adequados).

HelpMsg = vbcrlf & "  ShVerb" & vbcrlf & vbcrlf & "  David Candy 2014" & vbcrlf & vbcrlf & "  Lists or runs an explorer verb (right click menu) on a file or folder" & vbcrlf  & vbcrlf & "    ShVerb <filename> [verb]" & vbcrlf & vbcrlf & "  Used without a verb it lists the verbs available for the file or folder" & vbcrlf & vbcrlf
HelpMsg = HelpMsg & "  The program lists most verbs but only ones above the first separator" & vbcrlf & "  of the menu work when used this way" & vbcrlf & vbcrlf 
HelpMsg = HelpMsg & "  The Properties verb can be used. However the program has to keep running" & vbcrlf & "  to hold the properties dialog open. It keeps running by displaying" & vbcrlf & "  a message box." 
Set objShell = CreateObject("Shell.Application")
Set Ag = WScript.Arguments 
set WshShell = WScript.CreateObject("WScript.Shell") 
Set fso = CreateObject("Scripting.FileSystemObject")

    If Ag.count = 0 then 
        wscript.echo "  ShVerb - No file specified"
        wscript.echo HelpMsg 
        wscript.quit
    Else If Ag.count = 1 then 
        If LCase(Replace(Ag(0),"-", "/")) = "/h" or Replace(Ag(0),"-", "/") = "/?" then 
            wscript.echo HelpMsg 
            wscript.quit
        End If
    ElseIf Ag.count > 2 then 
        wscript.echo vbcrlf & "  ShVerb - To many parameters" & vbcrlf & "  Use quotes around filenames and verbs containing spaces"  & vbcrlf
        wscript.echo HelpMsg 
        wscript.quit
    End If

    If fso.DriveExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetFileName(Ag(0)))
'       Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
        Set objFolderItem = objFolder.self
        msgbox ag(0)
    ElseIf fso.FolderExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    ElseIf fso.fileExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    Else
        wscript.echo "  ShVerb - " & Ag(0) & " not found"
        wscript.echo HelpMsg 
        wscript.quit
    End If

    Set objVerbs = objFolderItem.Verbs

    'If only one argument list verbs for that item

    If Ag.count = 1 then
        For Each cmd in objFolderItem.Verbs
            If len(cmd) <> 0 then CmdList = CmdList & vbcrlf & replace(cmd.name, "&", "") 
        Next
        wscript.echo mid(CmdList, 2)

    'If two arguments do verbs for that item

    ElseIf Ag.count = 2 then
        For Each cmd in objFolderItem.Verbs
            If lcase(replace(cmd, "&", "")) = LCase(Ag(1)) then 
                wscript.echo(Cmd.doit)
                Exit For
            End If
        Next
    'Properties is special cased. Script has to stay running for Properties dialog to show.
        If Lcase(Ag(1)) = "properties" then
            WSHShell.AppActivate(ObjFolderItem.Name & " Properties")
            msgbox "This message box has to stay open to keep the " & ObjFolderItem.Name & " Properties dialog open."
        End If  
    End If
End If

Este é um excerto de um programa que cria um atalho

                Set SC = Sh.CreateShortcut(FolderMRUPath & "\" & CurrentDirName & ".lnk")
                SC.TargetPath = CurrentDirPath
                SC.Save
                SH.RegWrite MenuOrderKey, 0 , "REG_BINARY"
                wshshell.refreshmenu