Ações diferentes em url diferente: s

Question

Eu aprendi esse script

#IfWinActive, ahk_exe chrome.exe
   #u::send ^t
#IfWinActive, ahk_exe notepad.exe
   #u::send ^n
#IfWinActive, ahk_exe notepad++.exe
   #u::send ^!s

Agora, posso obter a mesma chave para executar ações diferentes em diferentes programas. Mas o que dizer de um passo adiante: ações diferentes em URLs diferentes: s no chrome.

Por exemplo, no Toggl.com eu quero ^! e fazer ação x, e no Checkvist.com eu quero ^! e fazer ação y.

Eu imagino fazer algo como

Send ^L
set clipboard to send ^c
Look if it matches with "toggl", if it does: do x.
Look if it matches with "checkvist", if it does: do y.

    

Answer 1

#IfWinActive, ahk_exe chrome.exe
   ^!vk45:: ; crtl+alt+e
      WinGetTitle, winTitle, % "A"
      If winTitle~="^Toggl\s"
         TrayTip,, % "first action"
      Else If winTitle~="^Checkvist:\s"
         TrayTip,, % "second action"
      Else
         TrayTip,, % "third action"
      winTitle:=""
      Return

Ou:

#IfWinActive, ahk_exe chrome.exe
   ^!vk45:: ; crtl+alt+e
      SendEvent, ^{vk4C} ; crtl+l
      clipContent:=ClipboardAll
      SendEvent, ^{Ins}
      ClipWait, .5
      If ErrorLevel
      {
         TrayTip, % "Error", % "Clipboard is empty!",, 3
         Clipboard:=clipContent
         Return
      }
      clipURL:=Clipboard
      Clipboard:=clipContent
      If clipURL~="toggl.com"
         TrayTip,, % "first action"
      Else If clipURL~="checkvist.com"
         TrayTip,, % "second action"
      Else
         TrayTip,, % "third action"
      clipURL:=""
      Return