Formatando uma planilha do Excel ao copiar / colar de um site

Question

Estou tentando criar um banco de dados no site . Cada país tem um monte de agentes, com detalhes de contato ao lado de seu nome (o número de fax e o nome da empresa não são necessários).

O problema é que, devido ao formato do site , quando Eu copio os dados em minha planilha do Excel, cada agente tem informações espalhadas por 3 ou 4 linhas.

Eu preciso que cada agente tenha todas as informações em uma linha,

por exemplo (Células em colchetes)

[ A1 ]       [ B1 ]             [ C1 ]  [ D1 ]                     [ E1 ]  [ F1 ]
GRO Alberti  [email protected]  Bosnia  P Hora K2 A 8 41 Dhjetori  Girana  Tel:[phone].

Eu tentei copiar tudo manualmente, mas isso demora muito.

Existe alguma maneira automática ou mais rápida de alcançar o que estou tentando fazer?

    

Answer 1

Se você quiser usar fórmulas do Excel:

• copie e cole a tabela no Excel
  • as linhas nas primeiras 2 colunas serão mescladas, mas as fórmulas podem ver o valor apenas na célula superior esquerda da área mesclada, outras células aparecem em branco para as fórmulas
• supondo que os dados iniciem na célula A2 , adicione a seguinte fórmula na célula E2 - a nova linha é inserida por Alt + Enter :

  =C2 & IF($A3<>"", "", "
  " & E3)

• copie a fórmula para o intervalo apropriado
• filtre pela coluna Name , excluindo (Blanks)
• ocultar as colunas Address e Other info originais
• copiar & colar especial como valores em uma nova planilha

O algoritmo subjacente é:

1. inicie na linha inferior
2. se Name em 1 linha abaixo não estiver vazio, crie uma nova string S contendo Endereço desta linha
   mais adicionar texto do endereço nesta linha para o início de S
3. mover uma linha para cima

Answer 2

Não sei exatamente como você está obtendo o valor de C1, mas você deve conseguir a origem da página. Para fazer isso, pressione Ctrl + U . Isso deve lhe dar uma página escrita em html. Procure a linha 128 (ou onde a tabela começa, deve haver os dados que você precisa lá e começa com <table class ... .

Copie tudo de <table class ... para </table> , que está na mesma linha, perto do fim.

Cole isso no bloco de notas.

Clique em Ctrl + H e use Localizar: <br /> Substitua por: "" (um espaço em branco) e pressione substituir todos.

Copie tudo e cole no excel. Você pode remover a formatação depois disso para uniformizar as dimensões da célula.

Observe que os hiperlinks permanecerão nos dados.

EDITAR:

Para separar o email, telefone, celular e fax será um pouco mais longo, mas não tanto tempo.

Para receber o e-mail, use essa fórmula na próxima célula de E2:

=LEFT(D2, FIND(" ",D2)-1)

E arraste para baixo.

Para obter os números agora, será mais fácil começar primeiro todos eles separadamente na coluna F:

=MID(D2, FIND(" ",D2)+1, LEN(D2))

Agora, em G, vamos buscar o Tel. Em H, recebemos o fax e, em I, obteremos o celular.

No G2, coloque e arraste para baixo:

=IFERROR(MID(F2,FIND("Tel:",F2)+4,IFERROR(FIND(":",F2,FIND("Tel:",F2)+4),LEN(F2))-FIND("Tel:",F2)-4),"")

No H2, coloque e arraste para baixo:

=IFERROR(MID(F2,FIND("Fax:",F2)+4,IFERROR(FIND(":",F2,FIND("Fax:",F2)+4),LEN(F2))-FIND("Fax:",F2)-4),"")

Em I2, coloque e arraste para baixo:

=IFERROR(MID(F2,FIND("Mobile:",F2)+7,IFERROR(FIND(":",F2,FIND("Mobile:",F2)+7),LEN(F2))-FIND("Mobile:",F2)-7),"")

Depois disso, copie tudo e cole como valores para remover fórmulas. Selecione as colunas G para I e substitua todas as Tel , Fax e Mobile por nada através de Ctrl + H .

As funções francesas em ordem mencionadas acima:

=GAUCHE(D2, TROUVE(" ",D2)-1)

=STXT(D2, TROUVE(" ",D2)+1, NBCAR(D2))

=SIERREUR(STXT(F2,TROUVE("Tel:",F2)+4,SIERREUR(TROUVE(":",F2,TROUVE("Tel:",F2)+4),NBCAR(F2))-TROUVE("Tel:",F2)-4),"")

=SIERREUR(STXT(F2,TROUVE("Fax:",F2)+4,SIERREUR(TROUVE(":",F2,TROUVE("Fax:",F2)+4),NBCAR(F2))-TROUVE("Fax:",F2)-4),"")

=SIERREUR(STXT(F2,TROUVE("Mobile:",F2)+7,SIERREUR(TROUVE(":",F2,TROUVE("Mobile:",F2)+7),NBCAR(F2))-TROUVE("Mobile:",F2)-7),"")