Existe uma configuração de registro para forçar a impressão de linhas de grade, cabeçalhos de coluna para o Excel 2007 no Windows XP?

Question

Acho que já sei a resposta para isso ("NÃO!"), mas achei que gostaria de chegar e esperar que alguém pudesse provar que estou errado.

Eu tenho muitas (dezenas de milhares) de planilhas do Excel que eu imagino (imprimindo em TIFF) para um cliente. Eles acabaram de adicionar uma nova ruga para solicitar as linhas de grade e os cabeçalhos de coluna nos TIFFs resultantes.

Existe uma maneira de forçar isso do registro? Ou seria necessário abrir cada documento e verificar as caixas corretas?

    

Answer 1

Eu não sei de nenhuma configuração de registro para isso, mas imagino que se todos os documentos a serem impressos estivessem em uma única pasta, não seria muito difícil lidar com uma macro. exemplo de trabalho abaixo.

Sub GridsHeaders()
    Dim FSO As Object
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Dim FLS As Object, F As Object
    Dim fWB As Workbook, fSheet As Worksheet
    Dim Loc As String

    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Select Folder"
        .AllowMultiSelect = False
        If .Show <> -1 Then Exit Sub
        Loc = .SelectedItems(1)
    End With

    Set FLS = FSO.GetFolder(Loc).Files
    For Each F In FLS
        Loc = UCase(Mid(F.Name, InStrRev(F.Name, ".") + 1))
        If Loc = "XLS" Or Loc = "XLSX" Then
            Set fWB = Workbooks.Open(F.Path)
            For Each fSheet In fWB.Sheets
                fSheet.PageSetup.PrintGridlines = True
                fSheet.PageSetup.PrintHeadings = True
            Next fSheet
            fWB.Close True
        End If
    Next F
End Sub