documento do PowerPoint bloqueado - possivelmente relatando usuário incorreto

Question

Recebi recentemente uma ligação de um dos usuários dizendo que sua apresentação do PowerPoint (Office 2007) estava bloqueada e editada por outra (ela estava trabalhando remotamente fora do servidor Citrix), mas a parte estranha é que o usuário Supostamente editando o arquivo foi longe de sua mesa com o PC desligado, nunca sequer ouviu falar dessa apresentação do PowerPoint, muito menos editar. Como isso é possível?

A apresentação do PowerPoint estava na unidade compartilhada, as pessoas bloqueiam o PC quando saem de suas mesas, as senhas não são comuns e são forçadas a serem alteradas a cada 90 dias.

O que poderia causar isso?

    

Answer 1

As informações sobre quem está usando um documento são provenientes das configurações de registro do Office. Eu não posso dizer com certeza que este é o seu problema apenas que eu vi aplicativos do Office com inválidos em muitos lugares com informações inválidas. Minha aposta é que alguém estava editando o documento, mas apenas tinha nomes / iniciais incorretos no Office.

Na minha rede, resolvi isso criando um script de login que redefinia o nome de usuário do Office no momento do logon. Isso é testado para o Office 2010, o nome de usuário / iniciais pode estar em algum lugar no registro de 2007. A mesma ideia deve ser aplicada.

Option Explicit

Dim WindowsDomain
WindowsDomain = "example.org"

Dim WshShell
Set WshShell = WScript.CreateObject("WScript.Shell")
Dim WshNetwork
Set WshNetwork = CreateObject("WScript.Network")

Dim User
Set User = GetObject("WinNT://" & WindowsDomain & "/" & WshNetwork.UserName & ",user")

Dim SplitName
SplitName = Split(User.Fullname, " ", 3)

Dim Initials, NamePart

Initials = ""

For Each NamePart in SplitName
  Initials = Initials & Left(NamePart,1)
Next

Initials = Left(Initials,3)

WshShell.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Office\Common\UserInfo\UserInitials", Initials, "REG_SZ"
WshShell.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Office\Common\UserInfo\UserName", User.Fullname, "REG_SZ"