Script para recriar o perfil de email do Outlook 2010

Question

Eu preciso recriar uma carga de perfis de e-mail dos usuários no Outlook 2010. (É uma longa história!)

Para tentar reduzir o "erro do usuário", quero fazer o script disso, para que ele remova o perfil de e-mail do usuário e recria um substituto.

Isso é possível? Eu vi o Assistente de Manutenção do Cliente para o Outlook 2003, mas não consigo encontrar um equivalente para 2010.

    

Answer 1

O Outlook 2010 usará a configuração automática se você puder configurar os registros DNS apropriados. Isso não automatiza completamente o processo, mas reduzirá o processo para talvez 2-3 etapas e eliminará 90% do trabalho de configuração que eles precisam fazer. Tudo o que eles (em teoria) precisariam saber é o nome, endereço de e-mail e senha.

    

Answer 2

Estou assumindo uma única máquina aqui com um cliente do Outlook que não envolve o Exchange.

Quando atualizei minha máquina doméstica do XP / Office 2003 - > Win 7 / Office 2010, infelizmente notei que muitas das configurações do Outlook e configurações não estavam contidas no arquivo PST. Extraí essas informações do registro do usuário usado no XP e as importei para o registro do Win 7. Minhas configurações basicamente voltaram.

Minha preocupação específica é centralizada porque uso meu cliente do outlook para acessar muitas caixas de correio diferentes em máquinas diferentes. Mas isso funcionou e eu não tive que passar pelo esforço de adicionar manualmente (muito menos lembrar o que eu havia feito antes).

No seu caso, encontre a área específica no registro dos usuários, salve-a, faça a atualização.

BTW, atualizei recentemente a partir de 2003 --- > 2010 no trabalho e todas as minhas configurações sobreviveram e foram convertidas corretamente.

    

Answer 3

Eu tenho esse script como favorito, então as pessoas podem fazer isso sozinhos sempre que se deparam com um problema com o perfil do Outlook.

• Verifica se o usuário deseja executar o script.
• Fecha o Outlook.
• Limpa os perfis configurados no registro do usuário.
• Cria um novo perfil (* você pode editar o novo nome do perfil com% username%, se quiser.)
• Abre o Outlook com novo perfil para o usuário.

Script:

'
' Use this script when user's emails get stuck in Outbox
' l0c0b0x/jb put this one together 9/13/2012
' Change log
' 1.0 initial release
' 1.1 Added registry string to specify a default profile on the account
' -----------------------------------------------------------

' Ask user if they wish to continue with re-creation of their ouotlook profile
intAnswer = _
    Msgbox("This script will remove and recreate your outlook profile on this computer.  Would you like to continue?", _
        vbYesNo, "Reset Outlook Profile")

If intAnswer = vbYes Then

Else
    WScript.Quit
End If

' Close all instances of Outlook
Set objShell = CreateObject("WScript.Shell") 
Set objWmg = GetObject("winmgmts:") 
strWndprs = "select * from Win32_Process where name='outlook.exe'" 
Set objQResult = objWmg.Execquery(strWndprs) 
For Each objProcess In objQResult
    intReturn = objProcess.Terminate(1) 
Next

' Remove registry keys for Outlook Profile
On Error Resume Next
const HKEY_CURRENT_USER = &H80000001
strComputer = "."

Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\" &_ 
strComputer & "\root\default:StdRegProv")

strKeyPath = "Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles"
DeleteSubkeys HKEY_CURRENT_USER, strKeyPath

Sub DeleteSubkeys(reghive, KeyPath) 
    Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\" &_ 
strComputer & "\root\default:StdRegProv")
    objReg.EnumKey reghive, KeyPath, arrrSubkeys 

    If IsArray(arrrSubkeys) Then 
        For Each strrSubkey In arrrSubkeys 
            DeleteSubkeys reghive, KeyPath & "\" & strrSubkey 
        Next 
    End If 

    objReg.DeleteKey reghive, KeyPath 

End Sub
' Add registry key for new profile
strKeyPath = "Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\newprofile"
oReg.CreateKey HKEY_CURRENT_USER,strKeyPath

' Add registry string to specify default profile
strKeyPath = "Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles"
strValueName = "DefaultProfile"
strValue = "newprofile"
oReg.SetStringValue HKEY_CURRENT_USER,strKeyPath,strValueName,strValue

' Launch Outlook
objShell.Run "outlook.exe"