o windows inicia o nginx e o php-fpm em segundo plano no mesmo morcego

Question

Estou tentando criar um arquivo bat no Windows 10 para iniciar o nginx e o php-fpm em segundo plano. No momento eu posso fazer isso, mas a janela de comando (janela preta) permanece aberta. Se eu fechar a janela, o php-fpm também será encerrado.

aqui está o que eu adicionei em start.bat

@ECHO OFF
cd D:\servers\nginx-1.10.1\
echo Starting Nginx...
start /B cmd /K "D:\servers\nginx-1.10.1\nginx.exe"
echo Start Php-cgi...
start /B cmd /K "D:\servers\php-5.6.26\php-cgi.exe -b 127.0.0.1:9000 -c D:\servers\php-5.6.26\php.ini"
EXIT

isto é o que está impresso na janela preta:

Starting Nginx...
Start Php-cgi...

Eu quero que a janela feche automaticamente, mas mantenha o processo (nginx e php-fpm) em execução.

    

Answer 1

O php-cgi bloqueia a janela. Experimente a solução que os caras do nginx dão na sua página. PHP-FastCGI no Windows

    

Answer 2

Você pode ocultar a janela do console como uma das soluções para esse problema. É fácil fazer com os utilitários do CLI, como o hidcon . Para meu projeto, eu uso este script: start-server.cmd

@Echo Off
:: Portable nginx+php5+mysql for Windows
:: Inquisitor, 2016-2018
CD /D "%~dp0"

:: Settings
Set LogFile=.\%~n0.log
Set TimestampFormat=[%%Date%% %%Time:~,8%%]
Set WatcherTimeout=10

If "%~1"=="" (
    Start "" "%~dp0tools\hidcon" %~nx0 restart_hidden
    Call Echo.>>"%LogFile%"
    Call :Log Loader started
    Exit
)


Set Path=%~dp0tools;%~dp0nginx;%~dp0php-fpm;%~dp0mysql\bin;%Path%
::  ImageMagick 6.9.3-3
rem Set Path=%Path%;%~dp0modules\imagick6
::  ImageMagick 7.0.5.10
rem Set Path=%Path%;%~dp0modules\imagick7
::  FFMpeg 3.3.1
Set Path=%Path%;%~dp0modules\ffmpeg

Set Temp=%~dp0\tmp



:: MySQL
Call :Log Starting MySQL...
:start-mysql
PushD .\mysql\bin
Start mysqld --defaults-file=my.ini --standalone
PopD
If "%1"=="restart" (
    Call :Log MySQL crashed, restarting
    Exit /B
)

:: PHP
Call :Log Starting PHP-FPM...
:start-php
PushD .\php-fpm
Start hidcon php-cgi -b 127.0.0.1:9123 -c ".\php.ini"
PopD
If "%1"=="restart" (
    Call :Log PHP-FPM crashed, restarting
    Exit /B
)

:: nginx
Call :Log Starting NginX...
:start-nginx
PushD .\nginx
Start nginx
PopD
If "%1"=="restart" (
    Call :Log NginX crashed, restarting
    Exit /B
)



TaskKill /F /IM "hidcon.exe"

For %%A In ("mysqld.exe", "php-cgi.exe", "nginx.exe") Do (
    wmic process where name="%%~A" CALL setpriority "high priority"
)



Set LockFile=.\.%~n0.lock
Echo.>"%LockFile%"

:Watcher
Ping -n %WatcherTimeout% 127.0.0.1>nul 2>nul
TaskList /FI "imagename EQ php-cgi.exe" /FO:CSV|FindStr /I /C:"php-cgi.exe">nul||Call :start-php restart
If Not Exist "%LockFile%" (
    Call :Log Lockfile not found, starting shutdown process

    PushD .\nginx
    nginx -s stop
    PopD

    mysqladmin -u root -pPCIIctvYUijcfNLR shutdown

    TaskKill /F /T /IM php-cgi.exe

    Call :Log Loader stopped
    Exit
)
GoTo :Watcher

:Log
    Call Echo %TimestampFormat% %*>>"%LogFile%"
Exit /B

e simples stop-server.cmd :

@Echo Off
Del "%~dp0.loader.lock" 2>nul