Não é possível o namespace root \ MSCluster da Consulta WMI como Administrador Local

Question

Estou tentando usar o WMI Explorer para consultar o namespace root \ MSCluster em vários hosts para obter dados do grupo de recursos de cluster e do objeto de recurso. Eu posso acessar o namespace sem nenhum problema nos nós do cluster Win2K3, mas estou recebendo um erro de acesso negado ao tentar se conectar aos nós Win2K8 e Win2K8R2.

Eu posso acessar o namespace root \ cimv2 sem nenhum problema, apenas o namespace do MSCluster, embora eu seja um administrador local. Existe uma configuração de recurso, diretiva de segurança local ou função de servidor que eu tenho que ser um membro para acessar o namespace?

    

Answer 1

Não está familiarizado com o WMI Explorer, mas permite especificar o ImpersonationLevel?

Experimente o VBScript (não testado) na máquina local. Em seguida, edite a linha strComputer="." para ser o nome do servidor e execute remotamente:

On Error Resume Next

Dim strComputer
Dim objWMIService
Dim colClusterNodes
Dim objClusterNode

strComputer = "."

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate,authenticationLevel=pktPrivacy}!\" & strComputer & "\root\mscluster")
If Err.Number <> 0 Then
    WScript.Echo "ERROR : Failed to get WMI handle [" & Err.Description & "]"
    Err.Clear
Else

    Set colClusterNodes = objWMIService.ExecQuery( "Select * from MSCluster_Node")
    If Err.Number <> 0 Then
        WScript.Echo "ERROR : Failed to execute WMI query [" & Err.Description & "]"
        Err.Clear
    Else 

        For Each objClusterNode in colClusterNodes
            Wscript.Echo "Caption : " & objClusterNode.Caption
            Wscript.Echo "State   : " & objClusterNode.State
            Wscript.Echo "Status  : " & objClusterNode.Status
            WScript.Echo ""
    Next

        Set colClusterNodes = Nothing
    End If

    Set objWMIService = Nothing
End If