alterar TTL em SOA com dnscmd

Question

Oi eu estou usando o comando dnsmcd no meu windows server 2012, a fim de criar novas zonas de arquivo csv.

Mas eu preciso mudar o TTL no registro SOA, então eu tento fazer isso:

dnscmd /recordadd example.com '@ 300 SOA

mas eu tenho esse erro:

Command failed:  DNS_ERROR_RECORD_FORMAT     9702    0x25E6

existe uma maneira de fazer isso?

    

Answer 1

Heres o formato correto para modificar um registro de início de autoridade

dnscmd /recordadd zonename @ SOA primaryDNSservername responsibleemailipaddress serialnumber refreshinterval retryinterval expireinterval defaultTTL

    

Answer 2

Se você está se perguntando por que está recebendo este erro DNS_ERROR_RECORD_ALREADY_EXISTS ao tentar alterar o registro SOA (ou seja, aumentar o número de série da zona), verifique se a serial para a qual você está alterando um novo) é realmente maior do que o atual. Esta mensagem de erro é confusa, por isso espero que lhe poupe um pouco a cabeça até descobrir o motivo.

Eu usei este script se você achar útil, porque clicar em "aumentar" em zonas de 200 ou mais foi demais para mim.

rem  To increase serial on all zones: copy this to a script, as functions cannot be use from CLI

echo on

rem  get the intersting zones first that you want to change
echo. > %TEMP%\dnszones.txt
for /f %%z in ('dnscmd /enumzones ^| findstr in-addr.arpa') do echo %%z >> %TEMP%\dnszones.txt

rem  take existing serials from all zones
for /f %%z in (%TEMP%\dnszones.txt) do dnscmd /zoneprint %%z | findstr SOA > %TEMP%\dns.%%z.txt

rem  read the serials and increase them
for /f %%z in (%TEMP%\dnszones.txt) do for /f "tokens=1-8*" %%a in (%TEMP%\dns.%%z.txt) do call:increase_serial %%z %%e

goto end

:increase_serial
rem arg1=%~1 is the zone name, arg2 is existing serial
@rem  example format of the SOA record
@rem         3600 SOA   servername.domain.com. hostmaster.domain.com. 13 900 600 86400 3600

@rem  as per https://technet.microsoft.com/en-us/library/cc816941(v=ws.10).aspx
@rem  var a is minimum-default-ttl - optional
@rem  var b is string SOA
@rem  var c is PrimSvr - server name with dot
@rem  var d is Admin - contact for admin
@rem  var e is serial
@rem  var f is Refresh - in seconds
@rem  var g is Retry - in seconds
@rem  var h is Expire - in seconds
@rem  var i is MinTTL - in seconds

set /a INCREASED_SERIAL=%~2+1
@echo increase serial from %~2 to %INCREASED_SERIAL% on zone %1
for /f "tokens=1-8*" %%a in (%TEMP%\dns.%~1.txt) do dnscmd /RecordAdd %~1 @ SOA %%c %%d %INCREASED_SERIAL% %%f %%g %%h %%i
goto :eof

:end