Converter string em data e hora em gawk ou awk

Question

Eu quero converter a seguinte string ( 20140805234656 ) em data e hora ( 2014-08-05 23:46:56 ). Sou novo no Gawk e não sei a sintaxe exata, como posso colocar - a cada 5,8 e : a cada 14,17 e colocar "" no índice 11. Existe alguma maneira eficiente de conseguir isso no awk?

EDITAR

Por favor, note que eu tenho string como variável em awk.I gerou durante o processamento de registros.

    

Answer 1

Uma maneira de fazer isso usando o GNU awk é esta:

echo 20140805234656 | awk 'BEGIN { FIELDWIDTHS = "4 2 2 2 2 2" } { printf "%s-%s-%s %s:%s:%s\n", $1, $2, $3, $4, $5, $6 }'

    

Answer 2

Você pode usar substring da seguinte forma:

echo 20140805234656 | awk '{print substr($0,1,4)"-"substr($0,5,2)"-"substr($0,7,2)" "substr($0,9,2)":"substr($0,11,2)":"substr($0,13,2) }'

Provavelmente também existem formas mais fáceis.

    

Answer 3

Outra resposta do GNU awk

gawk -v timestamp=20140805234656 '
    BEGIN {
        if (match(timestamp, /(....)(..)(..)(..)(..)(..)/, m)) {
            t = mktime(m[1] " " m[2] " " m[3] " " m[4] " " m[5] " " m[6])
            print strftime("%F %T", t)
            print strftime("%c", t) 
        }
    }
'

2014-08-05 23:46:56
Tue Aug  5 23:46:56 2014

    

Answer 4

Outra abordagem do awk do GNU:

result = gensub("(....)(..)(..)(..)(..)", "\1-\2-\3 \4:\5:", 1, your_variable)

    

Answer 5

Tente:

echo 20140805234656 | awk ' { printf "%s-%s-%s %s:%s:%s", 
                                     substr($0,1,4),
                                     substr($0,5,2),
                                     substr($0,7,2),
                                     substr($0,9,2),
                                     substr($0,11,2),
                                     substr($0,13,2)
                             } '

Ou, se você quiser associá-lo a uma variável primeiro:

echo 20140805234656 | awk ' { d=sprintf ("%s-%s-%s %s:%s:%s", 
                                     substr($0,1,4),
                                     substr($0,5,2),
                                     substr($0,7,2),
                                     substr($0,9,2),
                                     substr($0,11,2),
                                     substr($0,13,2));
                              print "Date is: " d
                             } '

    

Answer 6

Outra maneira:

$ echo 20140805234656 |
  awk '{split($0,a,"");printf("%s-%s-%s %s:%s:%s\n",a[1]a[2]a[3]a[4],a[5]a[6],a[7]a[8],a[9]a[10],a[11]a[12],a[13]a[14])}'
2014-08-05 23:46:56