Como colocar a saída das linhas à direita do grep on-line?

Question

Supondo que eu tenha este arquivo:

 Thu May  8 15:32:07 2014
        User-Name = "Mark"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564

    Thu May  8 15:32:07 2014
        User-Name = "Mike"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564
    Thu May  8 15:32:07 2014
        User-Name = "Mike"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564

    Thu May  8 15:32:07 2014
        User-Name = "Mark"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564

Eu consegui obter as informações relacionadas a um usuário usando grep com -A option:

grep -A4 "Mark" test
        User-Name = "Mark"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564
--
        User-Name = "Mark"
        Framed-IP-Address = 0.0.0.0
        Acct-Status-Type = Interim-Update
        Acct-Input-Octets = 95684
        Acct-Output-Octets = 23564

mas minha saída desejada é algo assim:

User-Name = "Mark" 
            Acct-Input-Octets = 95684 95684
            Acct-Output-Octets = 23564 23564

quando notamos que eu quero eliminar as duas primeiras linhas depois de "Mark" Framed-IP-Address = 0.0.0.0 , Acct-Status-Type = Interim-Update e colocar todos os valores do mesmo campo na mesma linha?

como Warwick sugere, a primeira parte da minha pergunta pode ser facilmente respondida:

grep -A4 "Mark" test| grep -v Framed-IP-Address | grep -v Acct-Status-Type

Note que este é um exemplo, o arquivo pode conter muita seção com User-Name="Mark" e a saída desejada será algo assim:

User-Name = "Mark" 
                Acct-Input-Octets = val1 val2 val3 val4 .......
                Acct-Output-Octets = val1 val2 val3 val4 ........

    

Answer 1

search.awk

BEGIN {
    FS = "="
    cur_username = ""
}

$1 ~ /User-Name/ {
    cur_username = $2
    gsub(/^[ \t]+/, "", cur_username)
    gsub(/[ \t]+$/, "", cur_username)
}

$1 !~ /User-Name/ {
    if ((NF != 2) || (cur_username != searched_user))
        next

    key = $1
    gsub(/^[ \t]+/, "", key)
    gsub(/[ \t]+$/, "", key)

    value = $2
    gsub(/^[ \t]+/, "", value)
        gsub(/[ \t]+$/, "", value)

    values[key] = values[key] " " value
}

END {
    printf("User-Name = %s\n", searched_user)
    for(key in values) {
        printf("\t%s =%s\n", key, values[key])
    }
}

Execução de teste:

$ awk -f search.awk -v 'searched_user="Mark"' input 
User-Name = "Mark"
    Acct-Status-Type = Interim-Update Interim-Update
    Acct-Input-Octets = 95684 95684
    Framed-IP-Address = 0.0.0.0 0.0.0.0
    Acct-Output-Octets = 23564 23564

Bônus - group.awk para agrupar todos os registros (muito ruim nawk não tem asorti ):

BEGIN {
    FS = "="
    cur_username = ""
}

$1 ~ /User-Name/ {
    cur_username = $2
    gsub(/^[ \t]+/, "", cur_username)
    gsub(/[ \t]+$/, "", cur_username)
}

$1 !~ /User-Name/ {
    if (NF != 2)
        next

    key = $1
    gsub(/^[ \t]+/, "", key)
    gsub(/[ \t]+$/, "", key)

    value = $2
    gsub(/^[ \t]+/, "", value)
        gsub(/[ \t]+$/, "", value)

    users[cur_username,key] = users[cur_username,key] " " value
}

END {
    n = asorti(users, sorted)
    prev_username = ""
    for (i=1; i<=n; i++) {
        username_key = sorted[i]
        split(username_key, a, SUBSEP)
        username = a[1]
        key = a[2]
        value = users[sorted[i]]
        if (username != prev_username) {
            printf("User-Name = %s\n", username)
            prev_username = username
        }
        printf("\t%s =%s\n", key, value)
    }
}

Execução de teste:

$ gawk -f group.awk input 
User-Name = "Mark"
    Acct-Input-Octets = 95684 95684
    ...
User-Name = "Mike"
    Acct-Input-Octets = 95684 95684
    ...

    

Answer 2

Você poderia fazer algo como

awk -vRS= -F'\n' '$2 ~ /Mark/ {
  vals["User-Name"] = "Mark"
  for (i=5;i<=NF;i++) {
    split($i,a," = ");
    vals[a[1]]=sprintf("%s %s", vals[a[1]], a[2]);
  }
}     
END{for (i in vals) print i,"=",vals[i];}' test

que, para o seu arquivo test , fornece

User-Name = Mark
        Acct-Input-Octets =  95684 95684
        Acct-Output-Octets =  23564 23564

    

Answer 3

1. Filtre os parágrafos desejados para coletar os dados sobre esse usuário.
2. Filtre as linhas contendo as chaves desejadas ( Acct-Input-Octets e Acct-Output-Octets ). Você pode querer normalizar o espaçamento neste estágio, se não for consistente.
3. Ordena entradas por chave (usando uma classificação estável, a menos que você não se importe com a ordem dos valores).
4. Recolher sequências de chaves idênticas.

awk -v RS= '/User-Name = "Mark"/' |
grep -E 'Acct-(Input|Output)-Octets *=' |
sort -k1,1 -s |
awk '
  BEGIN {printf "User-Name = \"Mark\""}
  $1 == key { printf " %s", $3; }
  $1 != key { key = $1; printf "\n%s", $0; }
  END { print "" }'