Melhorando minhas habilidades AWK

Question

Este programa funciona como eu pretendia, mas eu sinto que eu usei alguns métodos desajeitados para obter o resultado desejado (especialmente com o meu uso de comandos de impressão e declarações de variáveis)

Alguém poderia melhorar este script para que eu possa ver onde eu poderia melhorar?
Alguém quer me mostrar uma versão maluca disso?
Está definindo variáveis no bloco BEGIN que "executa todas as linhas! @ #! # @!" como você deve definir uma variável no AWK?

#!/usr/bin/awk -f
BEGIN{
FS=",";
recordsCursor=1;
number=0;
#spacer="_";
#copies=3;
}
{
    while(number++ <=copies){
        while(recordsCursor <= NF){
            if(recordsCursor==1){
            printf($recordsCursor);
            printf(spacer);
            printf("%.3d,",number);
            }else if(NF != recordsCursor){
                printf("%s," , $recordsCursor);
                }else{
                printf("%s" , $recordsCursor);
                }
        recordsCursor++;
        }
    recordsCursor=1;
    print "";
    }
print "";
number=0;
}

Command: ./test.awk -v copies=3 -v spacer=_ input

Dado entrada:

madison_Leaderboard_728x90,728x90,Leaderboard ads for Madison,no,,,,,,,_blank,image,web
madison_Bullseye_300x250,300x250,Bullseye ads for Madison,no,,,,,,Bullseye,_blank,image,web
madison_Button_155x155,155x155,Button ads for Madison,no,,,,,,,_blank,image,web

Saída correta:

madison_Leaderboard_728x90_001,728x90,Leaderboard ads for Madison,no,,,,,,,_blank,image,web
madison_Leaderboard_728x90_002,728x90,Leaderboard ads for Madison,no,,,,,,,_blank,image,web
madison_Leaderboard_728x90_003,728x90,Leaderboard ads for Madison,no,,,,,,,_blank,image,web
madison_Leaderboard_728x90_004,728x90,Leaderboard ads for Madison,no,,,,,,,_blank,image,web

madison_Bullseye_300x250_001,300x250,Bullseye ads for Madison,no,,,,,,Bullseye,_blank,image,web
madison_Bullseye_300x250_002,300x250,Bullseye ads for Madison,no,,,,,,Bullseye,_blank,image,web
madison_Bullseye_300x250_003,300x250,Bullseye ads for Madison,no,,,,,,Bullseye,_blank,image,web
madison_Bullseye_300x250_004,300x250,Bullseye ads for Madison,no,,,,,,Bullseye,_blank,image,web

madison_Button_155x155_001,155x155,Button ads for Madison,no,,,,,,,_blank,image,web
madison_Button_155x155_002,155x155,Button ads for Madison,no,,,,,,,_blank,image,web
madison_Button_155x155_003,155x155,Button ads for Madison,no,,,,,,,_blank,image,web
madison_Button_155x155_004,155x155,Button ads for Madison,no,,,,,,,_blank,image,web

    

Answer 1

awk -v copies=3 -v spacer=_ '
  BEGIN {OFS=FS=","} 
  {
    field1 = $1
    for (i=1; i <= copies+1; i++) {
      $1 = sprintf("%s%s%03d", field1, spacer, i)
      print
    }  
    print ""
  }
'

Isso tira proveito do awk recalculando $ 0 se algum dos campos alterar o valor.