encontra duplicado na primeira, segunda colunas e soma os números na terceira coluna

Question

Eu tenho esta entrada:

Fred apples 20
Susy oranges 5
Mark watermellons 12
Robert pears 4
Robert oranges 17
Terry oranges 9

Lisa peaches 7
Susy oranges 12
Mark grapes 39
Anne mangoes 7
Greg pineapples 3
Oliver rockmellons 2
Betty limes 14

e quero uma saída assim:

Anne:
         mangoes  7
Oliver:
     rockmellons  2
Greg:
      pineapples  3
Mark:
    watermellons 12
          grapes 39
Terry:
         oranges  9
Susy:
         oranges 17
Lisa:
         peaches  7
Fred:
          apples 20
Robert:
         oranges 17
           pears  4
Betty:
           limes 14

Estou tentando fazer isso com o comando awk. Meu código é assim:

{
lines[$1] = (lines[$1] ? lines[$1] "\n  "   $2 " "  $3 :  $1 ":\n       " $2 " " $3)


    }
    END {
        for (line in lines) print lines[line]
        }

Eu para comparar duplicatas na segunda coluna e somar os números.

    

Answer 1

Usando o GNU awk, que possui arrays de arrays (pode requerer o gawk versão 4)

gawk '
    NF  { n[$1][$2] += $3 }
    END {
        for (name in n) {
            print name ":"
            for (fruit in n[name]) 
                printf "%16s %2d\n", fruit, n[name][fruit]
        }
    }
'

    

Answer 2

Se você não se importar em ter a saída classificada, você pode acompanhar a pessoa atual e a fruta atual e soma até que ela mude:

#!/usr/bin/awk -f

NF {
    if (who != $1) {
        if (count > 0) {
            printf "%16s %2d\n", fruit, count
        }
        who = $1
        printf "%s:\n", who
        fruit = ""
        count = 0
    }
    if (fruit != $2) {
        if (count > 0) {
            printf "%16s %2d\n", fruit, count
        }
        fruit = $2
        count = $3
    } else {
        count += $3
    }
}

END {
    printf "%16s %2d\n", fruit, count
}

Alimente isso com sort -k1,1 -k2,2 :

sort -k1,1 -k2,2 file.txt | ./script.awk