make mutt mostra apenas uma instância de um cabeçalho

Question

Como um mutt pode exibir APENAS a última instância de um cabeçalho específico.

Em muitos casos, como g.e. Mensagens UCE ou phishing, a última (ou mais antiga) de várias linhas "Received:" é a de interesse para obter uma idéia da origem da correspondência. Existe uma maneira de fazer com que o mutt exiba apenas a última instância do cabeçalho "Recebido:"?

    

Answer 1

Você pode usar display_filter :

3.54 display_filter

Type: path
Default: (empty)

When set, specifies a command used to filter messages. When a message is viewed it is passed as standard input to $display_filter, and the filtered message is read from the standard output.

Isso requer algum outro comando que possa ler uma mensagem do stdin e filtrar os cabeçalhos "Recebidos" de acordo. por exemplo.

$ cat last-rec.sed
0,/^$/{ # only process headers
    :hdr
    /^Received:/{
        h # overwrite any previous Received line
        :fold
        # read next line without printing current
        N
        s/^.*\n//
        /^[[:space:]]/{
            H # append to current Received line
            b fold
        }
        b hdr
    }
    /^$/{
        # show final received line
        x
        p
        # and the empty line
        x
    }
}

(Isso tem o efeito colateral de mover a linha restante Received: abaixo de todos os outros cabeçalhos.)

Em seguida, configure-o em muttrc :

set display_filter="sed -f /path/to/last-rec.sed"