Cole vários arquivos csv grandes com ordem de cabeçalho diferente

Question

Eu tenho vários arquivos csv grandes em uma pasta e estou tentando rbind (concatenar) eles em um csv. Mas, ao fazer isso, quero ter certeza de que todos os valores de colunas vão para uma coluna apropriada após a concatenação. Eu não posso fazer isso em R por causa da limitação de memória. Eu sou muito novo no shell de scripts e sei que pode haver alguma maneira de fazer isso sem levar todos os arquivos csv para a memória.

Por exemplo.

> csv1
     A  B  C  D  E
     1  2  4  5  6
     4  5  7  8  9
     3  5  6  7  8
     2  3  4  5  8

> csv1
    C  B  E  D  A
    10 22 43 35 66
    14 15 37 48 99
    33 25 56 67 88

> Desired Output
         A  B  C  D  E
         1  2  4  5  6
         4  5  7  8  9
         3  5  6  7  8
         2  3  4  5  8
        66 22 10 35 43
        99 15 14 48 37
        88 25 33 67 56

Minhas tentativas:

Eu tento definir a ordem das colunas em R para cada arquivo enquanto salvo e depois uso o código abaixo para concatenar. Eu quero saber uma maneira onde eu possa fazer tudo no shell do linux.

Minha tentativa:

nawk 'FNR==1 && NR!=1{next;}{print}' *.csv > result.csv


Any help is highly appreciated.

Solução de RavindraSingh13 -

awk '
BEGIN{
  PROCINFO["sorted_in"] = "@ind_num_asc"
}
FNR==1{
  for(i=1;i<=NF;i++){
     a[$i]=i};
  if(FNR==1 && FNR==NR){
     print};
  next
}
{
  for(j in a){
     printf("%s ",$a[j])}
  print ""
}
' csv1 csv2

Mas, na solução acima, ele está pulando algumas linhas durante a concatenação.

    

Answer 1

Solução

GNU awk . Porém, mapeará todos os valores na memória.

merge_by_headers.awk script:

#!/bin/awk -f

BEGIN{ PROCINFO["sorted_in"] = "@ind_str_asc" }
NR==1 || FNR==1{ 
    for (i=1; i<=NF; i++) map[i] = $i; 
    c = NF; next 
}
NR==FNR{ 
    row_cnt = NR-1; 
    for (i=1; i<=NF; i++) a[map[i]][row_cnt] = $i; 
    next 
}
{ 
    row_cnt += 1; 
    for (i=1; i<=NF; i++) a[map[i]][row_cnt] = $i; 
}
END{
    delete map; h = ""; 
    for (k in a) h = (h? h OFS:"")k; 
    print h; 
    for (i=1; i<=row_cnt; i++) { 
        cnt = c; 
        for (k in a) printf "%d%s", a[k][i], (--cnt? OFS : ORS) 
    }
}

Uso:

awk -f merge_by_headers.awk 1.csv 2.csv | column -t

A saída:

A   B   C   D   E
1   2   4   5   6
4   5   7   8   9
3   5   6   7   8
2   3   4   5   8
66  22  10  35  43
99  15  14  48  37
88  25  33  67  56