zsh parse erro depois do alias do =…

Question

Eu tenho o seguinte arquivo .zshrc em meu diretório pessoal:

# modify the prompt to contain git branch name if applicable
git_prompt_info() {
  current_branch=$(git current-branch 2> /dev/null)
  if [[ -n $current_branch ]]; then
    echo " %{$fg_bold[green]%}$current_branch%{$reset_color%}"
  fi
}
setopt promptsubst
export PS1='${SSH_CONNECTION+"%{$fg_bold[green]%}%n@%m:"}%{$fg_bold[blue]%}%c%{$reset_color%}$(git_prompt_info) %# '

# load our own completion functions
fpath=(~/.zsh/completion $fpath)

# completion
autoload -U compinit
compinit

# load custom executable functions
for function in ~/.zsh/functions/*; do
  source $function
done

# makes color constants available
autoload -U colors
colors

# enable colored output from ls, etc
export CLICOLOR=1

# history settings
setopt hist_ignore_all_dups inc_append_history
HISTFILE=~/.zhistory
HISTSIZE=4096
SAVEHIST=4096

# awesome cd movements from zshkit
setopt autocd autopushd pushdminus pushdsilent pushdtohome cdablevars
DIRSTACKSIZE=5

# Enable extended globbing
setopt extendedglob

# Allow [ or ] whereever you want
unsetopt nomatch

# vi mode
bindkey -v
bindkey "^F" vi-cmd-mode
bindkey jj vi-cmd-mode

# handy keybindings
bindkey "^A" beginning-of-line
bindkey "^E" end-of-line
bindkey "^R" history-incremental-search-backward
bindkey "^P" history-search-backward
bindkey "^Y" accept-and-hold
bindkey "^N" insert-last-word
bindkey -s "^T" "^[Isudo ^[A" # "t" for "toughguy"

# aliases
[[ -f ~/.aliases ]] && source ~/.aliases

# extra files in ~/.zsh/configs/pre , ~/.zsh/configs , and ~/.zsh/configs/post
# these are loaded first, second, and third, respectively.
_load_settings() {
  _dir="$1"
  if [ -d "$_dir" ]; then
    if [ -d "$_dir/pre" ]; then
      for config in "$_dir"/pre/**/*(N-.); do
        . $config
      done
    fi

    for config in "$_dir"/**/*(N-.); do
      case "$config" in
        "$_dir"/pre/*)
          :
          ;;
        "$_dir"/post/*)
          :
          ;;
        *)
          if [ -f $config ]; then
            . $config
          fi
          ;;
      esac
    done

    if [ -d "$_dir/post" ]; then
      for config in "$_dir"/post/**/*(N-.); do
        . $config
      done
    fi
  fi
}
_load_settings "$HOME/.zsh/configs"

# Local config
[[ -f ~/.zshrc.local ]] && source ~/.zshrc.local

Infelizmente, quando eu inicio meu terminal, recebo o seguinte erro:

/home/steven/.zshrc:72: parse error near 'fi'

O problema parece estar em meus arquivos aliases. Eu tenho dois arquivos de aliases: 1. .aliases 2. .aliases.local

.aliases é carregado e dentro dele há o seguinte comando para carregar .aliases.local :

[[ -f ~/.aliases.local ]] && source ~/.aliases.local

Dentro do meu arquivo .aliases.local eu tenho os dois seguintes aliases:

alias server='ssh -p xxx [email protected]'
alias do='ssh -L xxxx:127.0.0.1:xxxx -N -f -l user -p xxxx xx.xx.xxx.xxx'

Estes são basicamente aliases para ssh no meu servidor (o primeiro alias), e também para estabelecer um túnel seguro para que eu possa usar um cliente VNC para o servidor.

Esses dois aliases estão funcionando corretamente, mas quando os defino em .aliases.local , continuo recebendo esse erro. O que estou fazendo de errado?

    

Answer 1

do é uma palavra reservada no shell. Faz parte da sintaxe de while e for loops. Quando você define como um alias, o alias tem precedência sobre a palavra reservada. Então o shell vê, após a expansão do alias:

if [ -d "$_dir/pre" ]; then
  for config in "$_dir"/pre/**/*(N-.); ssh -L xxxx:127.0.0.1:xxxx -N -f -l user -p xxxx xx.xx.xxx.xxx
    . $config
  done
fi

Eu não sei por que o zsh está reclamando sobre o fi e não sobre o done ou a falta de do após o ponto-e-vírgula, mas de qualquer forma, essa não é uma sintaxe válida.

Você precisa escolher um nome diferente para o seu alias. Evite todas as palavras reservadas .