sed linhas de contagem entre padrão - vários arquivos

Question

Eu tenho vários arquivos .txt em um diretório. Cada arquivo tem uma seção:

DONE
item 1
item 2
item 3
DONE

Gostaria de contar o número de linhas entre os dois marcadores DONE para cada arquivo separadamente.

Eu usei esta pergunta para criar isto:

sed -n "/DONE/,/DONE/ p" *.txt | wc -l > ~/word_count.txt

Mas isso combina as contagens de cada arquivo em um número. Em vez disso, gostaria de uma saída assim:

file1.txt 3
file2.txt 5
file3.txt 6

    

Answer 1

Melhor uso de awk para contagem .

awk '
  FNR == 1 {inside = 0}
  $0 == "DONE" {
    if (inside) print FILENAME, n
    n = 0
    inside = ! inside
    next
  }
  inside {n++}' ./*.txt

Isso imprimirá um registro para cada seção DONE...DONE em cada arquivo, o que significa que nada será impresso se não houver tal seção. Para imprimir 0 para esses, você precisaria da implementação GNU de awk com suas declarações especiais BEGINFILE , ENDFILE :

awk '
  BEGINFILE {DONE_count = 0}
  $0 == "DONE" {
    if (++DONE_count % 2 == 0) print FILENAME, n
    n = 0
    next
  }
  DONE_count % 2 {n++}
  ENDFILE {if (!DONE_count) print FILENAME, 0}' ./*.txt

Ou execute um awk por arquivo:

for file in ./*.txt; do
  awk '
    $0 == "DONE" {
      if (++DONE_count % 2 == 0) print FILENAME, n
      n = 0
      next
    }
    DONE_count % 2 {n++}
    END {if (!DONE_count) print FILENAME, 0}' "$file"
done

    

Answer 2

perl -lne '
   eof and !$a && print "$ARGV: ", 0+$a;          # no DONEs => ans=0
   next unless /DONE/ && !$a ... /DONE/;          # skip non-DONE ranges
   /DONE/ and !$a++ && next;                      # begin DONE range
   !/DONE/ and !eof and $a++,next;                # middle of DONE range
   !/DONE/ and eof and $a=2;                      # lone DONE => ans=0
   print "$ARGV: ", ($a-2, $a=0, close ARGV)[0];  # end of DONE range
                                                  # at the end we do 4 things: 1) subtract 2 from sum, 2) print filename+sum, 3) reset sum, and 4) skip the current file and jump to the next file in queue.
' ./*.txt

Com sed , podemos fazer isso por arquivo:

for f in ./*.txt; do
   printf '%s: %d\n' "$f" "$(sed -e '/DONE/,/DONE/!d; //d' "$f" | wc -l)"
done

A diferença estará no cenário em que não teremos um DONE de encerramento.