Alterando duas strings na mesma linha combinadas por um regex

Question

Eu tenho um número de variáveis em um arquivo .dat que eu mudei automaticamente com um script. Um desses arquivos tem um parâmetro, bar , organizado como tal em um arquivo .dat:

var1  var2   var3  foo  bar
T     T      T     100  100

Eu costumava usar as seguintes linhas de um script bash para alterar o valor da barra de um valor inicial arbitrário para o valor desejado, neste caso, 2000. Este script mudaria 'bar' para 2000.

LINE1=$(awk '/bar/ {++n;if (n==1) {print FNR}}' data.dat)
((LINE1=$LINE1 + 1))
OLD1=$(awk '{for(i=1;i<'$LINE1';i++) getline}{print $12}' data.dat)
sed -i '' "${LINE1}s/$OLD1/2000/" data.dat

No entanto, agora preciso alterar foo ao lado de bar . Neste exemplo, isso está definindo foo e bar para 2000.

LINE1=$(awk '/foo/ {++n;if (n==1) {print FNR}}' data.dat)
((LINE1=$LINE1 + 1))
OLD1=$(awk '{for(i=1;i<'$LINE1';i++) getline}{print $12}' data.dat)
sed -i '' "${LINE1}s/$OLD1/2000/" data.dat

LINE1=$(awk '/bar/ {++n;if (n==1) {print FNR}}' data.dat)
((LINE1=$LINE1 + 1))
OLD1=$(awk '{for(i=1;i<'$LINE1';i++) getline}{print $12}' data.dat)
sed -i '' "${LINE1}s/$OLD1/2000/" data.dat

Isso só alterou o foo para 2000, deixando bar inalterado. Eu percebo que isso é um problema com a maneira como descrevi a expressão regular, mas não consegui alterar as duas variáveis com uma expressão awk / sed.

    

Answer 1

Você pode fazer

awk -v newvalue=2000 '
    NR == 1 {
        for (i=1; i<=NF; i++) {
            if ($i == "foo") i_foo=i
            if ($i == "bar") i_bar=i
        }
    }
    NR == 2 {$i_foo = $i_bar = newvalue}
    {print}
' file.dat | column -t

var1  var2  var3  foo   bar
T     T     T     2000  2000

Ou com menos hard-coding no awk

awk -v cols="var2=1234,bar=5678" '
    BEGIN {
        n = split(cols, a, /[=,]/)
        for (i=1; i<n; i+=2) newval[a[i]] = a[i+1]
    }
    NR == 1 { for (i=1; i<=NF; i++) if ($i in newval) idx[$i] = i }
    NR == 2 { for (col in idx) $(idx[col]) = newval[col] }
    {print}
' file.dat | column -t

  

var1  var2  var3  foo  bar
T     1234  T     100  5678

    

Answer 2

Apenas por diversão:

awk -F'\t' -vOFS='\t' -vfoovalue=2101 -vbarvalue=2102 '
             /foo/&&/bar/{
                           row=NR
                           for(i=1;i<=NF;i++){
                                               if($i=="foo"){colfoo=i}
                                               if($i=="bar"){colbar=i}
                                              }
                           print
                          }
             NR==row+1{ $colfoo=foovalue; $colbar=barvalue; print }
            ' file

var1    var2    var3    foo         bar
T       T       T       2101        2102