GNUPlot: conjunto de terminais desconhecido

Question

    G N U P L O T
    Version 4.6 patchlevel 4    last modified 2013-10-02 
    Build System: Linux x86_64

    Copyright (C) 1986-1993, 1998, 2004, 2007-2013
    Thomas Williams, Colin Kelley and many others

    gnuplot home:     http://www.gnuplot.info
    faq, bugs, etc:   type "help FAQ"
    immediate help:   type "help"  (plot window: hit 'h')
    Terminal type set to 'unknown'
    gnuplot>

Oi, o gnuplot me mostra o tipo de terminal definido como 'desconhecido'.
E se eu digitar o seguinte comando.

gnuplot> plot "./MergePlot.dat" with linespoint

Nada acontece.

    

Answer 1

Você definitivamente não compreendeu como usar o gnuplot.
Você não disse ao gnuplot o que ele tem para traçar.

E qual deve ser a saída.

Por favor, leia o manual. Caso contrário, ninguém irá ajudá-lo se você não leu o manual. link

Caso contrário, aqui está um exemplo de como um gráfico de trabalho seria como comandos.

#SET TERMINAL
set term svg
set output 'temp-verlauf.svg'
set title "Temperaturverlauf"

#Axes label
set xlabel "Messzeitpunkt"
set ylabel "Luftfeuchte/Temperatur"
set y2label "Luftdruck"

#Axis setup
set xdata time # x-Achse wird im Datums/Zeitformat skaliert
set timefmt "%d.%m.%Y\t%H:%M:%S" # Format Zeitangaben yyyy.mm.dd_hh:mm:ss
set format x "%H:%M" # Format für die Achsenbeschriftung


#Axis ranges
set yrange [0:60] # die y-Achse geht von:bis

#Tics
set ytics nomirror
set y2tics nomirror

#OTHER
set datafile separator "\t"
set xrange ["06.11.2014 14:00:00":"07.11.2014   21:00:00"]

plot \
"file.dat" every 10 using 1:5 title "Luftfeuchte" with lines, \
"file.dat" every 10 using 1:6 title "Temperatur" with lines, \
"file.dat" every 10 using 1:7 title "Luftdruck" with lines axes x1y2, \
"file.dat" every 10 using 1:17 title "Niederschlagsintensitaet Synop (4677)" with lines

    

Answer 2

Configurando o terminal correto

O erro encontrado significa que o gnuplot não está reconhecendo um terminal válido. Você tem que definir um válido. Para conhecer a lista dos disponíveis, você pode perguntar na linha de comando do gnuplot

gnuplot> set terminal 

E ele responderá com algo como

Available terminal types:
       cairolatex  LaTeX picture environment using graphicx package 
                   and Cairo backend
           canvas  HTML Canvas object
              cgm  Computer Graphics Metafile
          context  ConTeXt with MetaFun (for PDF documents)
            corel  EPS format for CorelDRAW
             dumb  ascii art for anything that prints text

              ...  Many linees  ...

              gif  GIF images using libgd and TrueType fonts
             gpic  GPIC -- Produce graphs in groff using the 

              ...  Other linees  ...

Para cada um deles, você pode pedir ao gnuplot para mais informações, por exemplo, com help terminal gif .

Então você pode simplesmente configurar o terminal, se você tentar o mudo , é adorável.

gnuplot> set terminal dumb
gnuplot> plot 0.5*sin(x/2)  lt 0, cos(x/2)



    1 ++---------------+---------------####---------------+---------------++
      +                +             ##  + ##          0.5*sin(x/2) +....+ +
  0.8 ++                            #        #             cos(x/2) ######++
      |                            #          #                            |
  0.6 ++                          #            #                          ++
      |++++++                    #              #+++++++                   |
  0.4 ++    +++                 #             ++ #     +++                ++
      #       +++               #           ++   #        ++               #
  0.2 +#        ++            ##          ++      ##        +             #+
    0 +#          ++          #          ++        #         ++           #+
      | #          ++        #         ++           #         ++         # |
 -0.2 ++ #           +      #         ++             #          ++      # ++
      |  ##           ++    #       ++               #           +++   ##  |
 -0.4 ++   #            +++#      ++                  #            +++#   ++
      |     #             #+++++++                     #             #+++++|
 -0.6 ++    #             #                            #             #    ++
      |      ##         ##                              ##         ##      |
 -0.8 ++      #        #                                  #        #      ++
      +        ##    ###                 +                ###    ##        +
   -1 ++---------#####-+-----------------+----------------+-#####---------++
     -10              -5                 0                5                10

Se você não tiver a possibilidade de usar um terminal do qual "você pode ver" ( wxt , qt , x11 , aqua ...), use um formato gráfico e salve a saída em um arquivo externo. Desta forma, você irá criar um arquivo no diretório a partir do qual você executa o gnuplot.

set terminal png enhanced truecolor    # ... whatever ...
  set output 'tempfile.png'            # you need to redirect to a file the output 
    plot 0.5*sin(x/2)  lt 0, cos(x/2)  # your plot commands     
    # replot # it should be cosy if you are not doing multiplot 
  set out                              # restore the output redirection
set terminal GNUTERM                   # restore the default terminal

Nota:
Você pode precisar instalar os diferentes pacotes -qt,-nox,-x11 para ter recursos diferentes (o OP acabou de fazê-lo) ou para compilar sozinho para adicionar outros.