No OS X 10.7 (Lion), o Terminal.app suporta isso nativamente: New Windows/Tabs open in: Same working directory
Freqüentemente preciso abrir uma nova guia no mesmo diretório da minha guia atual para fazer outra coisa, enquanto minha guia atual é ocupada por um longo processo em execução. No entanto, por padrão, quando você cria uma nova guia, o Terminal.app começa em ~ /. Alguma idéia de como fazer isso pular automaticamente?
No OS X 10.7 (Lion), o Terminal.app suporta isso nativamente: New Windows/Tabs open in: Same working directory
É preciso ter muito cuidado ao passar cordas por diferentes ambientes.
Eu corro 10.4, então meu script "tfork" sempre abre uma nova janela. Deve ser fácil adaptá-lo para usar uma guia:
#!/bin/sh
# source: http://www.pycs.net/bob/weblog/2004/02/23.html#P49
# Rewritten to use osascript args -> run handler args.
# Added ability to pass additional initial command and args to new shell.
# Bug: Non ASCII characters are unreliable on Tiger.
# Tiger's osascript seems to expect args to be encoded in
# the system's primary encoding (e.g. MacRoman).
# Once in AppleScript, they are handled OK. Terminal sends them
# back to the shell as UTF-8.
test $# -eq 0 && set -- : # default command if none given
osascript - "$(pwd)" "$@" <<\EOF
on run args
set dir to quoted form of (first item of args)
set cmd_strs to {}
repeat with cmd_str in rest of args
set end of cmd_strs to quoted form of cmd_str
end
set text item delimiters to " "
set cmd to cmd_strs as Unicode text
tell app "Terminal" to do script "cd " & dir & " && " & cmd
end
EOF
Exemplo: tfork git log -p ..FETCH_HEAD
Alteração: cwd de um processo já em andamento "ocupando" uma guia Terminal
A idéia de “o diretório atual do programa ocupando a aba atual” não é tão óbvia quanto se poderia esperar.
Cada aba Terminal tem um único dispositivo tty que é usado pelos processos que ele executa (inicialmente, um shell; depois disso, qualquer que seja o início do shell).
Cada terminal (normal) tty possui um único grupo de processos em primeiro plano que pode ser considerado como "ocupando" o tty.
Cada grupo de processos pode ter vários processos.
Cada processo pode ter seu próprio diretório de trabalho atual (cwd) (alguns ambientes dão a cada segmento seu próprio equivalente em cwd ou cwd, mas vamos ignorar isso).
Os fatos anteriores estabelecem um tipo de trilha que vai de tty a cwd: tty - > grupo de processos em primeiro plano - > processos do grupo de processos em primeiro plano - > cwds.
A primeira parte (do tty ao primeiro plano) do problema pode ser resolvida com a saída de ps :
ps -o tty,pid,tpgid,pgid,state,command | awk 'BEGIN{t=ARGV[1];ARGC=1} $1==t && $3==$4 {print $2}' ttyp6
(onde “ttyp6” é o nome do tty de interesse)
O mapeamento do processo (PID) para cwd pode ser feito com lsof :
lsof -F 0n -a -p 2515,2516 -d cwd
(onde "2515,2516" é uma lista separada por vírgulas dos processos de interesse)
Mas sob Tiger, não vejo nenhuma maneira direta de obter o nome do dispositivo tty de uma determinada janela Terminal . Há uma maneira terrivelmente feia de obter o nome tty em Tiger. Talvez o Leopard ou o Snow Leopard possam fazer melhor.
Eu coloquei tudo junto em um AppleScript assim:
on run
(* Find the tty. *)
-- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
tell application "Terminal"
set w to window 1
tell w
set origName to name
set title displays device name to not title displays device name
set newName to name
set title displays device name to not title displays device name
end tell
end tell
set tty to extractTTY(origName, newName)
if tty is "" then
display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the PIDs of the processes in the foreground process group on that tty. *)
set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
BEGIN {t=ARGV[1];ARGC=1}
$2==t && $3==$4 {print $1}
' " & quoted form of tty)
if pids is {} or pids is {""} then
display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the unique cwds of those processes. *)
set text item delimiters to {","}
set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
set cwds to {}
repeat with lsofItem in text items of lsof
if lsofItem starts with "n" then
set cwd to text 2 through end of lsofItem
if cwds does not contain cwd then ¬
set end of cwds to cwd
end if
end repeat
if cwds is {} then
display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
if length of cwds is greater than 1 then
set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
if cwds is false then error number -128 -- cancel
end if
(* Open a new Terminal. *)
tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds
end run
to extractTTY(a, b)
set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
set offs to offset of "tty" in str
if offs > 0 then
return text offs through (offs + 4) of str
end if
return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
set text item delimiters to space
if class of big is not list then set big to text items of big
if class of little is not list then set little to text items of little
set {maxLen, minLen} to {length of big, length of little}
if maxLen < minLen then ¬
set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}
set start to missing value
repeat with i from 1 to minLen
if item i of big is not equal to item i of little then
set start to i
exit repeat
end if
end repeat
if start is missing value then
if maxLen is equal to minLen then
return ""
else
return items (minLen + 1) through end of big as Unicode text
end if
end if
set finish to missing value
repeat with i from -1 to -minLen by -1
if item i of big is not equal to item i of little then
set finish to i
exit repeat
end if
end repeat
if finish is missing value then set finish to -(minLen + 1)
return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail
Salve com Editor de Script ( Editor AppleScript no Snow Leopard) e use um lançador (por exemplo, FastScripts ) para atribuí-lo a uma chave (ou apenas executá-lo no menu AppleScript (ativado via / Applications / AppleScript / AppleScript Utility.app )).
Eu publiquei um script que usa O código de Chris Johnsen acima e outro script para abrir a nova guia no diretório atual com as configurações atuais, principalmente porque eu coordeno em cores os meus terminais. Obrigado Chris, por esse roteiro, eu tenho usado isso há alguns meses e é uma grande economia de tempo.
(* Esse script abre uma nova guia Terminal.app no diretório da guia atual com as mesmas configurações. Você precisará, se ainda não tiver feito isso, ativar o acesso a dispositivos de assistência, conforme descrito aqui: link
É quase todo o trabalho de dois roteiros juntos, obrigado a eles:
O script de Chris Johnsen abre uma nova guia no diretório atual: OS X Terminal.app: como iniciar uma nova aba no mesmo diretório da aba atual?
O "menu_click" de Jacob Rus me permite criar a guia com as mesmas configurações, pois a API do Terminal não: link
Se você alterar o nome de um perfil do Terminal, a API do AppleScript retornará o nome antigo até que você reinicie o aplicativo, para que o script não funcione nas configurações renomeadas até então. Ugh. Além disso, a necessidade de ativar o Terminal para executar o comando de menu traz todas as janelas do terminal para a frente.
*)
-- from http://hints.macworld.com/article.php?story=20060921045743404
-- 'menu_click', by Jacob Rus, September 2006
--
-- Accepts a list of form: '{"Finder", "View", "Arrange By", "Date"}'
-- Execute the specified menu item. In this case, assuming the Finder
-- is the active application, arranging the frontmost folder by date.
on menu_click(mList)
local appName, topMenu, r
-- Validate our input
if mList's length < 3 then error "Menu list is not long enough"
-- Set these variables for clarity and brevity later on
set {appName, topMenu} to (items 1 through 2 of mList)
set r to (items 3 through (mList's length) of mList)
-- This overly-long line calls the menu_recurse function with
-- two arguments: r, and a reference to the top-level menu
tell application "System Events" to my menu_click_recurse(r, ((process appName)'s ¬
(menu bar 1)'s (menu bar item topMenu)'s (menu topMenu)))
end menu_click
on menu_click_recurse(mList, parentObject)
local f, r
-- 'f' = first item, 'r' = rest of items
set f to item 1 of mList
if mList's length > 1 then set r to (items 2 through (mList's length) of mList)
-- either actually click the menu item, or recurse again
tell application "System Events"
if mList's length is 1 then
click parentObject's menu item f
else
my menu_click_recurse(r, (parentObject's (menu item f)'s (menu f)))
end if
end tell
end menu_click_recurse
-- with the noted slight modification, from https://superuser.com/questions/61149/os-x-terminal-app-how-to-start-a-new-tab-in-the-same-directory-as-the-current-ta/61264#61264
on run
(* Find the tty. *)
-- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
tell application "Terminal"
set w to the front window
tell w
set origName to name
set title displays device name to not title displays device name
set newName to name
set title displays device name to not title displays device name
end tell
end tell
set tty to extractTTY(origName, newName)
if tty is "" then
display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the PIDs of the processes in the foreground process group on that tty. *)
set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
BEGIN {t=ARGV[1];ARGC=1}
$2==t && $3==$4 {print $1}
' " & quoted form of tty)
if pids is {} or pids is {""} then
display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the unique cwds of those processes. *)
set text item delimiters to {","}
set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
set cwds to {}
repeat with lsofItem in text items of lsof
if lsofItem starts with "n" then
set cwd to text 2 through end of lsofItem
if cwds does not contain cwd then ¬
set end of cwds to cwd
end if
end repeat
if cwds is {} then
display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
if length of cwds is greater than 1 then
set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
if cwds is false then error number -128 -- cancel
end if
(* Open a new Terminal. *)
-- Here is where I substituted the menu_click call to use the current settings
tell application "Terminal"
activate
tell window 1
set settings to name of current settings in selected tab
end tell
end tell
menu_click({"Terminal", "Shell", "New Tab", settings})
tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds in selected tab of window 1
end run
to extractTTY(a, b)
set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
set offs to offset of "tty" in str
if offs > 0 then
return text offs through (offs + 6) of str
end if
return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
set text item delimiters to space
if class of big is not list then set big to text items of big
if class of little is not list then set little to text items of little
set {maxLen, minLen} to {length of big, length of little}
if maxLen < minLen then ¬
set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}
set start to missing value
repeat with i from 1 to minLen
if item i of big is not equal to item i of little then
set start to i
exit repeat
end if
end repeat
if start is missing value then
if maxLen is equal to minLen then
return ""
else
return items (minLen + 1) through end of big as Unicode text
end if
end if
set finish to missing value
repeat with i from -1 to -minLen by -1
if item i of big is not equal to item i of little then
set finish to i
exit repeat
end if
end repeat
if finish is missing value then set finish to -(minLen + 1)
return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail
Como mencionado em outro lugar , se você estiver usando Oh meu Zsh , então você deve apenas adicionar o plugin terminalapp . No seu arquivo .zshrc (supondo que você já esteja usando o plugin git:
plugins=(terminalapp git)
Eu uso este alias / shell script para fazer isso.
# modified from http://www.nanoant.com/programming/opening-specified-path-in-terminals-new-tab
alias twd=new_terminal_working_directory
function new_terminal_working_directory() {
osascript <<END
tell application "Terminal"
tell application "System Events" to tell process "Terminal" to keystroke "t" using command down
do script "cd $(pwd)" in first window
end tell
END
}
http://www.entropy.ch/blog/Mac+OS+X/2008/06/27/Terminal-Tricks-“term”-revisited-with-tabs.html
tab -t $PWD