No Outlook2010, existe uma maneira de visualizar os lembretes de adiamento no momento?

Question

Existe alguma maneira no Outlook 2010 para abrir uma lista de itens que estão suspensos no momento? Por exemplo, digamos que duas semanas depois eu configurei um lembrete para aparecer na sexta-feira para uma importante reunião de almoço na segunda-feira seguinte (eu gostaria de me lembrar das tarefas de segunda-feira antes do final de semana). Quando o lembrete aparece na sexta-feira, eu o adio por três dias para que ele apareça novamente antes do almoço na segunda-feira. Em seguida, a segunda-feira rola e minha memória está confusa e estou um pouco paranóico por ter demitido acidentalmente o lembrete na sexta-feira, em vez de cochilar corretamente. Ainda posso ver o compromisso original no meu calendário, mas preciso garantir que estou realmente fazendo o lembrete aparecer quando eu quiser, para não perder minha reunião.

Existe alguma maneira no Outlook 2010 para obter uma lista dos lembretes que estão atualmente suspensos? Isso também seria útil para os casos em que concluo uma tarefa cujo lembrete eu tinha adiado até mais tarde, e agora quero extrair o lembrete adiado e cancelá-lo.

    

Answer 1

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Se você não estiver familiarizado com o VBA, consulte a página de explicação do Slipstick . Você encontrará informações sobre:

• configurações de segurança de macros;
• onde colocar o código (você pode usar um módulo regular com Insert | Module); e
• como criar um botão.

Answer 2

De acordo com esta postagem no fórum Exibir itens adiados , não é possível ver uma lista de itens adiados. A postagem sugere que você pode ver uma quantidade limitada de informações úteis criando uma visualização personalizada que exibe alguns dos campos de lembrete.

    

Answer 3

Tente clicar na guia Calendário, selecione Visualizar e Alterar visualização. Em seguida, selecione Lista. Isto parece mostrar uma lista de todos os lembretes.