Eu tive exatamente o mesmo problema com o meu aparelho de som do carro, 1 arquivo / 2 não é jogável, porque o jogador considera que o arquivo de ponto criado pelo MAC OS é um arquivo de música ...
Então achei esse post muito útil, obrigado.
Então eu volto agora com uma solução melhorada e gratuita para o Mavericks:
- Crie um aplicativo do Automator para executar um script AppleScript
-
Use este script:
on run {input, parameters}
try
tell application "Finder" to set allDrives to the name of every disk whose local volume is true and startup is false
set driveName to {choose from list allDrives with title "DiskCleaner" with prompt "Disk to Clean and Eject:" OK button name "Clean and Eject" cancel button name "Abort"} as text
set getDriveIdentifier to "diskutil info " & quoted form of driveName & " | grep Ident | awk '{print $3}'"
set driveIdentifier to do shell script getDriveIdentifier
try
do shell script "find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete"
do shell script "find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete"
do shell script "find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete"
do shell script "rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}"
display notification "Disk Cleaned"
on error
try
do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete" with administrator privileges
do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete" with administrator privileges
do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete" with administrator privileges
do shell script "sudo rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}" with administrator privileges
display notification "Disk Cleaned"
on error
display notification "Can't Clean, Permission Denied"
end try
end try
delay 1
try
do shell script "diskutil eject " & driveIdentifier
display notification "Disk Ejected"
on error
display notification "Can't Eject, Disk in Use"
end try
on error
display notification "No Disk to Clean and Eject"
end try
end run
-
Salve o aplicativo como DiskCleaner.app, por exemplo
Este script pedirá que você escolha o disco USB para limpar e ejetar. Em seguida, ele limpará o disco USB (tente com credenciais de administrador se falhar com as atuais) e, em seguida, ejete, se possível.
Claro que ainda há algum lugar para melhorar, eu fiz esse roteiro para mim!
Além disso, você tem a flexibilidade de adicionar linhas de código para limpar mais arquivos.
Aproveite!
