Hotkey global para mostrar / ocultar um aplicativo específico no OS X? [duplicado]

Question

É possível definir uma tecla de atalho global para mostrar / ocultar um aplicativo específico no OS X?

Por exemplo, eu quero ser capaz de mostrar / ocultar o Safari com Cmd + Espaço .

    

Answer 1

Abra o Automator , selecione para criar um Serviço , configure para que receba nenhuma entrada em qualquer aplicativo .

Na biblioteca, clique duas vezes em Utilitários »Executar o AppleScript e insira o seguinte na área de texto grande:

on run {input, parameters}

    tell application "System Events"
        set names to name of application processes
        if names contains "Safari" then
            tell application process "Safari"
                if visible then
                    set visible to false
                else
                    # use the following to simply have it reappear:
                    set visible to true
                    # use the following to focus Safari:
                    tell application "Safari" to activate
                end if
            end tell
        else
            display dialog "Safari is not running"
        end if
    end tell

    return input
end run

Salve sob qualquer nome. Atribui um atalho de teclado em Preferências do Sistema »Teclado» Atalhos de Teclado »Serviços . Lembre-se de desativar o atalho do Spotlight Cmd-Space .

    

Answer 2

Salve no Editor AppleScript e Atribuir um atalho para executar um script no OS X

tell application (path to frontmost application as text)
    if name is "TextEdit" then
        set bid to id
        tell application "System Events" to tell (process 1 where bundle identifier is bid)
            set visible to false
        end tell
    else
        tell application "TextEdit"
            reopen
            activate
        end tell
    end if
end tell

• Se o aplicativo de destino estiver no momento mais à frente, oculte-o
• Caso contrário, ative-o

Answer 3

CMD + W ocultará as janelas. Isso funciona globalmente. No entanto Para voltar a eles, você precisa estar clicando nos ícones da doca. Em um navegador, no entanto, fechará a guia.