É possível definir rapidamente todos os espaços para o mesmo papel de parede?

Question

É ótimo que o Lion permita que diferentes espaços tenham papéis de parede diferentes, mas não encontrei uma maneira fácil de fazer com que todos usassem o mesmo papel de parede.

A única maneira que consegui até agora foi alterar manualmente o papel de parede de cada espaço ou fechar todos os espaços (exceto aquele que tem o papel de parede que eu quero) e reabri-los.

Alguém tem uma solução para permitir que eu defina rapidamente todos os espaços para o mesmo papel de parede?

    

Answer 1

Você tem alguma solução?

Eu encontrei o mesmo problema, então criei uma solução rápida de hackear com o AppleScript:

set spacenumber to 4 -- how many spaces do you have?

-- Try to get number of spaces from System preferences
tell application "System Preferences"
    reveal anchor "shortcutsTab" of pane id "com.apple.preference.keyboard"
    tell application "System Events" to tell window "Keyboard" of process "System Preferences"
        set spacenumber to count (UI elements of rows of outline 1 of scroll area 2 of splitter group 1 of tab group 1 whose name begins with "Switch to Desktop")
    end tell
    quit
end tell

tell application "System Events"
    set _desktops to every desktop
    if (count of _desktops) > 1 then
        -- if you have multiple displat (eg: external monitor) ask which
        display dialog "Choose your screen." buttons (get display name of every desktop) default button 1
        set _display to the button returned of the result
    else
        -- else set the one display as selected
        set _display to display name of the first desktop
    end if

    set new_file to choose file with prompt "Choose an image."
    repeat with i from 0 to (spacenumber - 1)
        delay 1
        tell (every desktop whose display name is _display) to set picture to new_file as alias
        tell process "WindowServer" to key code {124} using control down -- Go to the next space
    end repeat
end tell

É bom para mim agora.

Atualização: number of spaces getter adicionado de: link