Como adiciono múltiplas fórmulas em uma célula?

Question

Aqui estão as fórmulas de que preciso, mas não consigo descobrir como combiná-las.

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"))
=IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified"))
=IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified"))
=IF(H4=4,IF(J30<=E32,"Pre-Qualified","Unqualified"))
=IF(H4=5,IF(J30<=E33,"Pre-Qualified","Unqualified"))
=IF(H4=6,IF(J30<=E34,"Pre-Qualified","Unqualified"))

    

Answer 1

Como você está testando 1 , 2 , 3 ,…, há uma resposta especial que funcionará para você:

=CHOOSE(H4, IF(J30<=E29,"Pre-Qualified","Unqualified"),
            IF(J30<=E30,"Pre-Qualified","Unqualified"),
            IF(J30<=E31,"Pre-Qualified","Unqualified"),
            IF(J30<=E32,"Pre-Qualified","Unqualified"),
            IF(J30<=E33,"Pre-Qualified","Unqualified"),
            IF(J30<=E34,"Pre-Qualified","Unqualified"))

Isso tem o mesmo efeito que a fórmula IF - THEN composta dada nas outras respostas.

Mas, porque as seis fórmulas internas são as mesmas, exceto por um elemento, você pode simplificar isso consideravelmente:

=IF(J30<=CHOOSE(H4, E29, E30, E31, E32, E33, E34), "Pre-Qualified", "Unqualified")

Uma diferença: as outras respostas serão avaliadas como FALSE se H4 não for 1 , 2 , 3 , 4 , 5 ou 6 , enquanto minhas respostas resultarão em um erro #VALUE! .

    

Answer 2

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"),
IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified")),
IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified")),
....)

Isso testará a segunda declaração se a primeira falhar. Então, se H4! = 1, ele testará H4 novamente 2 ...

    

Answer 3

Se as instruções forem IF, THEN, ELSE. Então coloque o próximo "IF" no lugar ELSE da última declaração IF.

=IF(H4=1,IF(J30<=E29,"Pre-Qualified","Unqualified"),
 IF(H4=2,IF(J30<=E30,"Pre-Qualified","Unqualified"),
 IF(H4=3,IF(J30<=E31,"Pre-Qualified","Unqualified")...)))

    

Answer 4

Você pode tentar uma declaração if e como esta:

=IF(AND(H1<4,J30<=E29),"Pre-Qualified","Unqualified")

você pode inserir múltiplas variáveis em sua instrução e se TODAS forem verdadeiras, retornará TRUE, se alguma não for verdadeira, retornará false. Outra coisa que você pode tentar é que =IF(OR( funcione da mesma forma que E, a menos que algum seja verdadeiro, ele retornará verdadeiro para toda a declaração.