Como “Responder a todos” e manter o anexo original no Outlook?

Question

Como posso executar uma "Resposta para todos" no Outlook, mas reenvie o anexo original para todos?

    

Answer 1

Aparentemente não sem algum código VBA. Aqui está uma coisa que descobri que pretende fazer exatamente isso. ( Fonte )

Descrição: Este exemplo de VBA do Outlook cria e exibe uma resposta para a mensagem atualmente aberta ou selecionada, incluindo os anexos no original.

Sub ReplyWithAttachments()
    Dim rpl As Outlook.MailItem
    Dim itm As Object

    Set itm = GetCurrentItem()
    If Not itm Is Nothing Then
        Set rpl = itm.Reply
        CopyAttachments itm, rpl
        rpl.Display
    End If

    Set rpl = Nothing
    Set itm = Nothing
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application

    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select

    Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
   strPath = fldTemp.Path & "\"
   For Each objAtt In objSourceItem.Attachments
      strFile = strPath & objAtt.FileName
      objAtt.SaveAsFile strFile
      objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
      fso.DeleteFile strFile
   Next

   Set fldTemp = Nothing
   Set fso = Nothing
End Sub

Notas sobre o código:

1. Usa a % funçãoGetCurrentItem() para retornar o item atualmente selecionado ou exibido. / p>

2. Usa o procedimento CopyAttachments() para copiar os anexos para a resposta.

3. Substitua itm.Reply por itm.ReplyAll se você preferir responder a todos.

(Ah, e achei isso em cerca de 30 segundos fazendo uma pesquisa na web por "responder a todos com anexos no outlook").

    

Answer 2

Solução possível:

A pessoa que envia este e-mail pela primeira vez abre sua pasta "Itens Enviados", abre o e-mail e seleciona Ações - "Reenviar esta mensagem ...." novamente.