encontrar um diretório e abri-lo no Windows com cmd

Question

há possivelmente qualquer maneira de encontrar o diretório de um arquivo ("example.txt") e, em seguida, se encontrar o arquivo abrir o diretório (como "c: \ example \ sub \") no cmd (ou vb )? é claro, procurando em todas as partições não apenas "C: \".

    

Answer 1

Execute o seguinte comando a partir da raiz de cada uma das suas unidades.

for /f "delims=" %a in ('dir /s /b example.txt') do explorer %~dpa

O comando acima irá encontrar todos os arquivos chamados "example.txt" e então executar o explorer no diretório onde eles estão localizados.

Se você deseja usar um arquivo de lote, cada % precisa ser substituído por %% :

for /f "delims=" %%a in ('dir /s /b example.txt') do explorer %%~dpa

Para obter uma lista de unidades:

for /f "skip=1 delims=" %a in ('wmic logicaldisk get caption') do @echo %a

Em um arquivo em lotes:

for /f "skip=1 delims=" %%a in ('wmic logicaldisk get caption') do @echo %%a

Colocando tudo junto em um arquivo de lote:

for /f "skip=1 delims=" %%a in ('wmic logicaldisk get caption') do (
    cd %%a
    cd \
    for /f "delims=" %%b in ('dir /s /b example.txt') do explorer %%~dpb
)

Para parar após o primeiro jogo:

for /f "skip=1 delims=" %%a in ('wmic logicaldisk get caption') do (
    cd %%a
    cd \
    for /f "delims=" %%b in ('dir /s /b example.txt') do (
        explorer %%~dpb
        exit
    )
)

    

Answer 2

Isso localizará todos os arquivos com as extensões fornecidas no diretório de trabalho atual e em todos os subdiretórios:

dir *.cpp *.h *.java /b/s

Isso fará isso para arquivos que começam com "pyth"

dir pyth*

você pode estender este exemplo.

Para abrir o local do arquivo (ou seja, a pasta), você pode cd para o resultado e digitar

explorer .

ou

start .

Se você não quiser usar cd , poderá passar o local do arquivo de dir para o comando explorer ou start .

Para adaptar isso a um loop para cada unidade montada, confira este post do Stackoverflow:

link