Atualização : na verdade, por causa de um obstáculo a essa pergunta e por "alguém fez essa pergunta", procurei por duplicatas:
Como tornar o Outlook 2010 não me avisar sobre uma linha de assunto vazia?
Responde a pergunta:
Option Explicit
'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================
Private WithEvents colInspectors As Outlook.Inspectors
Private Sub Application_Startup()
'---------------------------------------------------------------------
' Set a reference to all forms
'---------------------------------------------------------------------
Set colInspectors = Outlook.Inspectors
End Sub
Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)
'---------------------------------------------------------------------
' This code is running if a form (e. g. an e-mail) will be opened
'---------------------------------------------------------------------
Dim objItem As Object
'---------------------------------------------------------------------
' Skip errors
'---------------------------------------------------------------------
On Error GoTo ExitProc
'---------------------------------------------------------------------
' Set a reference to the open item
'---------------------------------------------------------------------
Set objItem = Inspector.CurrentItem
'---------------------------------------------------------------------
' A new item does not have a received time
'---------------------------------------------------------------------
If Year(objItem.ReceivedTime) = 4501 Then
'-----------------------------------------------------------------
' Check if the subject is empty if an e-mail was created by a
' template with predefined subject.
'-----------------------------------------------------------------
If objItem.Subject = "" Then objItem.Subject = " "
End If
ExitProc:
'---------------------------------------------------------------------
' Delete the reference to the form and to the item
'---------------------------------------------------------------------
Set objItem = Nothing
Set Inspector = Nothing
End Sub
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
On Error Resume Next
'---------------------------------------------------------------------
' If the blank still exists it will now be removed (Outlook®
' will this not recognize)
'---------------------------------------------------------------------
Item.Subject = Trim(Item.Subject)
End Sub
Private Sub Application_Quit()
'---------------------------------------------------------------------
' Delete the reference to the forms
'---------------------------------------------------------------------
Set colInspectors = Nothing
End Sub
Resposta antiga, para uma referência à explicação da escolha da Microsoft:
Por que alguém desejaria enviar um email com uma linha de assunto vazia? Você envia um e-mail com uma intenção e o assunto está lá para resumir isso. Deixar a linha de assunto vazia aumenta o nível de confiança de spam e seu e-mail pode ser visto como lixo eletrônico.
O Outlook foi projetado como um cliente de e-mail corporativo ou corporativo, não especificamente para uso pessoal / doméstico. Se você receber muitos e-mails, é mais fácil digitalizar através das linhas de assunto do que através dos corpos de conteúdo para determinar que ação tomar para cada e-mail ...
Nota: Muitos usuários sofreram com o envio de emails sem uma linha de assunto para que solicitassem à Microsoft que implementasse esse comportamento no Outlook 2010, você poderia solicitar a opção de mudar isso para que pudessem implementá-lo no próximo service pack. Experimente o atendimento ao cliente da Microsoft ...