Como extrair o descritor de Nível de Estrutura de Divisão de Trabalho no MS Excel

Question

Eu quero que minha estrutura WBS de terceiro nível seja retornada no excel, independentemente do tamanho do caractere.

Exemplos específicos: se minha WBS for 1.2.3.1, quero retornar 1.2.3 e, se minha WBS for 1.200.4.2, quero retornar 1.200.4. Em outras palavras, o comprimento dos caracteres entre os períodos não importa.

Eu estava usando LEFT() , mas isso não leva em consideração o tamanho do caractere. Qualquer ajuda seria apreciada.

    

Answer 1

Eu assumo que tudo que você precisa fazer é remover o terceiro "." e qualquer personagem que o segue. Nesse caso, e supondo que a string WBS esteja na célula A1, você pode usar

=LEFT(A1,SEARCH(".",A1,SEARCH(".",A1,SEARCH(".",A1)+1)+1)-1)

Se A1 contiver "1.200.4.2", isso retornará "1.200.4".

    

Answer 2

Esta fórmula extrairá o descritor de WBS Nível 3 do descritor completo armazenado em A1 :

=LEFT(A1,FIND("~",SUBSTITUTE(A1,".","~",3))-1)

Note que esta fórmula pode ser adaptada para extrair qualquer descritor de nível. Basta substituir o 3 pelo nível necessário.

Por exemplo, para extrair o descritor de nível 2, use:

=LEFT(A1,FIND("~",SUBSTITUTE(A1,".","~",2))-1)

Observe também que esta fórmula retornará um erro se um descritor que já é o Nível 3 for fornecido. O seguinte permite isso:

=
IFERROR(
  LEFT(A1,FIND("~",SUBSTITUTE(A1,".","~",3))-1),
  IFERROR(SUBSTITUTE(A1,".",".",2),NA())
)

Outra fórmula que você pode achar útil é esta:

=LEFT(A1,FIND("~",SUBSTITUTE(A1,".","~",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))-0))-1)

Retorna um nível ancestral. Note que esta fórmula também é multi-nível. Para retornar o ancestral dois níveis, substitua o -0 por -1 . Para três níveis acima, use -2 , etc.