Como faço para detectar se o uTorrent está baixando?

Question

Eu preciso escrever um script que determine se o uTorrent está ou não baixando alguma coisa. Eu prefiro que seja apenas baixar, mas se eu não posso diferenciar entre o download e upload, então seria melhor que nada.

Uma forma possível seria verificar se algum arquivo terminado em .!ut está bloqueado, mas espero algo um pouco mais elegante.

Minha arma de escolha é o VBScript, mas estou feliz em usar a linha de comando, se necessário.

    

Answer 1

Aqui está um pouco de VBScript que irá se conectar a um servidor web do uTorrent e determinar se alguma coisa está sendo baixada. Ele apresentará uma janela pop-up com uma mensagem apropriada.

Alguns pontos a serem observados:

• Você precisa ativar a "IU da Web" nas preferências do uTorrent e definir um nome de usuário e uma senha.
• É necessário modificar utServer , utUSERNAME e utPASSWORD neste código para o local e credenciais corretos para efetuar login. O valor de exemplo em utSERVER no código se conecta à máquina local (127.0. 0.1) na porta 8080.
• O uTorrent requer uma chamada inicial para obter um token válido para todas as solicitações subsequentes. Isso é armazenado em utToken . Você não precisa se preocupar com isso, apenas chame Request_uTorrent com o URL correto e ele funcionará se uma solicitação / atualização de token for necessária ou não.
• Um "download ativo" é considerado como aquele que possui um ETA maior que 0 segundo e não está sendo propagado. Se o ETA é infinito, então é considerado não baixar.
• A análise de JSON no VBScript é possível, mas não é fácil ( fonte ). Esse código usa alguma manipulação de string para obter os resultados como um CSV e, em seguida, analisa dessa maneira.
• Este código não é muito bom para lidar com erros causados quando o uTorrent não está sendo executado ou não está aceitando conexões de interface da web. A solução atual é usar o brutal On Error Resume Next , mas isso deve ser realmente limpo.
• O código pode ficar preso em um loop se ele não tiver um token, solicitar um, receber um, fazer o primeiro pedido novamente e (por algum motivo) o token for inválido. Não tenho certeza de como isso é possível, mas como qualquer coisa poderia facilmente (e acidentalmente) modificar o utToken , isso poderia acontecer. Você pode querer modificar isso para que, se o token falhar uma segunda vez, ele seja suspenso.
• A extração de tokens é algo totalmente ou nada. Se falhar, o código sai. Isso não é incrivelmente útil na depuração.

Salve o seguinte como check_downloading.vbs e clique duas vezes para executar:

Option Explicit

' Configuration settings
' utSERVER = The IP address and port of the uTorrent server
' utUSERNAME = The username
' utPASSWORD = The password

Const utSERVER = "127.0.0.1:8080"
Const utUSERNAME = "yourusername"
Const utPASSWORD = "yourpassword"
Dim utToken ' Required for the uTorrent token

' == Code starts here ==

If Is_Downloading = True Then
    Msgbox "Something is downloading"
Else
    Msgbox "Nothing is downloading"
End If
WScript.Quit

' Is_Downloading
' Connects to uTorrent and checks to see if anything is currently downloading.
' Returns True if there is. Note: A file with an infinite ETA is considered not
' downloading.

Function Is_Downloading
    Dim sContent, sItem, sLines, token

    ' Get a list of the torrents from uTorrent
    sContent = Request_uTorrent("list=1")

    ' Parsing JSON isn't the easiest in VBScript, so we make some
    ' simple changes to the output and it looks like comma seperated
    ' values.

    For Each sItem In Split(sContent, VbLf)
        If Left(sItem, 2) = "[""" Then
            ' Remove spaces and the first ["
            sItem = Trim(sItem) : sItem = Right(sItem, Len(sItem)-1)
            ' Remove the ends of lines finishing with either ]], or ],
            If Right(sItem, 3) = "]]," Then sItem = Left(sItem, Len(sItem)-3)
            If Right(sItem, 2) = "]," Then sItem = Left(sItem, Len(sItem)-2)

            ' Extract the values from the line
            token = Process_CSV_Line(sItem)

            ' Format of the token array is:
            '   0 = HASH (string),
            '   1 = STATUS* (integer),
            '   2 = NAME (string),
            '   3 = SIZE (integer in bytes),
            '   4 = PERCENT PROGRESS (integer in per mils),
            '   5 = DOWNLOADED (integer in bytes),
            '   6 = UPLOADED (integer in bytes),
            '   7 = RATIO (integer in per mils),
            '   8 = UPLOAD SPEED (integer in bytes per second),
            '   9 = DOWNLOAD SPEED (integer in bytes per second),
            '   10 = ETA (integer in seconds),
            '   11 = LABEL (string),
            '   12 = PEERS CONNECTED (integer),
            '   13 = PEERS IN SWARM (integer),
            '   14 = SEEDS CONNECTED (integer),
            '   15 = SEEDS IN SWARM (integer),
            '   16 = AVAILABILITY (integer in 1/65535ths),
            '   17 = TORRENT QUEUE ORDER (integer),
            '   18 = REMAINING (integer in bytes)

            ' The ETA (token 10) can have three values:
            '   -1 = The download has stalled (reported as "infinite" in the UI)
            '    0 = The download has completed.
            '   >0 = The number of seconds left.
            '
            ' However, the ETA also includes seeding so we need to also ensure that the percentage
            ' complete is less than 1000 (100%).

            If IsNumeric(token(10)) And CLng(token(10)) > 0 And IsNumeric(token(4)) And CLng(token(4)) < 1000 Then
                Is_Downloading = True
                Exit Function
            End If  
        End If
    Next
    Is_Downloading = False
End Function

' Process_CSV_Line
' Given a string, split it up into an array using the comma as the delimiter. Take into account
' that a comma inside a quote should be ignored.

Function Process_CSV_Line(sString)    
    Redim csv(0)
    Dim iIndex : iIndex = 0
    Dim bInQuote, i : bInQuote = False

    For i = 1 To Len(sString)
        Dim sChar : sChar = Mid(sString, i, 1)
        If sChar = """" Then
            bInQuote = Not bInQuote
            sChar = ""
        End If
        If sChar = "," And Not bInQuote Then
            iIndex = iIndex + 1
            Redim Preserve csv(iIndex)
            csv(iIndex) = ""
        Else
            csv(iIndex) = csv(iIndex) & sChar
        End If
    Next
    Process_CSV_Line = csv
End Function

' Request_uTorrent
' Given a URL, append the token and download the page from uTorrent

Function Request_uTorrent(sURL)
    Dim sAddress

    If utToken <> "" Then
        ' We have a token
        sAddress = "http://" & utSERVER & "/gui/?" & sURL & "&token=" & utToken
    ElseIf sURL <> "token.html" Then
        Call Get_uTorrent_Token
        Request_uTorrent = Request_uTorrent(sURL)
        Exit Function
    Else
        sAddress = "http://" & utSERVER & "/gui/token.html"
    End If

    ' Error handling is required in case uTorrent isn't running. This approach works, but could be much better.
    On Error Resume Next
    Dim oWeb : Set oWeb = CreateObject("MSXML2.XMLHTTP")
    oWeb.Open "GET", sAddress, False, utUSERNAME, utPASSWORD
    oWeb.Send
    Request_uTorrent = oWeb.ResponseText
    On Error Goto 0

    Set oWeb = Nothing

    ' If we get an "invalid request" then the token is out of date
    If Request_uTorrent = vbcrlf & "invalid request" Then
        Call Get_uTorrent_Token
        Request_uTorrent = Request_uTorrent(sURL)
        Exit Function
    End If
End Function

' Get_uTorrent_Token
' Connects to token.html on the uTorrent webserver to get a token that enables
' further API calls to be made. Called automatically by Request_uTorrent although
' can be called manually if performance is critical (reduces the calls by 1).

Sub Get_uTorrent_Token
    utToken = ""
    Dim sResponse : sResponse = Request_uTorrent("token.html")
    Dim re : Set re = New RegExp
    re.IgnoreCase = True
    re.Global = True
    re.Pattern = "<div.+?>(.+?)<\/div>"
    Dim m : Set m = re.Execute(sResponse)
    If m.Count > 0 Then
        utToken = m(0).SubMatches(0)
    Else
        ' Unable to extract token. Bail.
        WScript.Quit
    End If

    Set m = Nothing
    Set re = Nothing
End Sub

    

Answer 2

Para elaborar o comentário do iglvzx, você pode usar a API da Web do uTorrent para obter uma lista de torrents ativos . Para usar a API, tudo o que você precisa fazer é ativá-la nas configurações. Então, é uma simples chamada HTTP GET - pode ser para o host local se o seu script for executado na mesma máquina.