Como inserir números de referência não ingleses no Office 2010?

Question

Estou usando o Word 2010 (Professional Plus) em uma máquina Win 7. Estou digitando um documento em tibetano e gostaria que os números de referência (números de nota de rodapé e final) também estivessem em tibetano, mas eles não são, eles são apenas em caracteres ingleses (árabes). Eu tenho um problema semelhante com números de páginas, o que seria ótimo se ti pudesse ser corrigido, mas os números de referência são a preocupação mais premente.

Estou usando uma fonte unicode tibetana e um sistema de entrada de terceiros. Eu tenho Tibetano instalado como um idioma adicional no Office e também tenho instalado como um idioma e teclado no Windows, mas eu não estou usando o teclado tibetano do Windows. No entanto, tentei inserir referências ao usar o teclado tibetano do Win7 e ele ainda insere caracteres em árabe.

Meu idioma padrão para o computador, assim como o Office, é o inglês dos EUA.

Não consegui encontrar nenhuma ajuda on-line, na maioria das vezes, as perguntas sobre caracteres não ingleses no Office não têm respostas. Qualquer ajuda seria apreciada. Obrigado.

    

Answer 1

Outra abordagem seria usar o VBA para substituir todas as referências de notas de rodapé por uma seqüência de referências usando os glifos tibetanos. Eu acho que o seguinte faria isso para as notas de rodapé, supondo que você queira que cada nota de rodapé seja numerada dessa forma, e a numeração é contínua em todo o documento. Mas se você quisesse ver a numeração correta o tempo todo, você teria que executar essa macro toda vez que inserisse, excluísse ou re-sequenciasse uma nota de rodapé.

Sub replaceFootnoteRefsbyTibetanSequence()
Dim fsource As Word.Footnote
Dim ftarget As Word.Footnote
Dim lng As Long
Dim rsource As Word.Range
Dim rtarget As Word.Range
With ActiveDocument
  For lng = 1 To .Footnotes.Count
    Set rtarget = .Footnotes(lng).Reference.Duplicate
    rtarget.Collapse Direction:=wdCollapseEnd
    Set ftarget = rtarget.Footnotes.Add(rtarget, strTibetan(lng))
    rtarget.Style = ActiveDocument.Styles(Word.WdBuiltinStyle.wdStyleFootnoteReference).NameLocal
    ftarget.Range.FormattedText = .Footnotes(lng).Range.FormattedText
    .Footnotes(lng).Delete
    Set ftarget = Nothing
    Set rtarget = Nothing
  Next
End With

End Sub

Function strTibetan(theNumber As Long) As String
Dim i As Integer
Dim s As String
s = ""
For i = 1 To Len(CStr(theNumber))
  s = s & ChrW(AscW(Mid(CStr(theNumber), i, 1)) - AscW("0") + &HF20)
Next
strTibetan = s
End Function

Algo semelhante seria sem dúvida possível com notas finais. As coisas podem ser mais difíceis se houver numeração por página ou por seção.