Ver cabeçalho de email sem abrir a mensagem

Question

Eu gostaria de ver os cabeçalhos de e-mail da lista de mensagens em uma pasta sem abrir a mensagem primeiro.

Isso é possível?

    

Answer 1

Pessoalmente, coloco o botão na barra de ferramentas de acesso rápido do Outlook (QAT). Para fazer isso, basta clicar no menu suspenso no canto superior esquerdo da janela do Outlook e selecionar "Mais Comandos ...". Na caixa de diálogo "Personalizar barra de ferramentas de acesso rápido", selecione "Todos os comandos" na lista "de" e Adicionar > > o botão "Opções de Mensagem ..." na lista à direita. Clique em OK e você está lá.

Agora você pode selecionar a mensagem desejada na lista e clicar nesse novo botão no QAT para mostrar "Cabeçalhos da Internet".

    

Answer 2

Defina um botão para chamar a macro VBA a seguir para exibir o cabeçalho do e-mail atualmente selecionado:

Public Sub mailHeaderView()
    Dim exp As Explorer
    Dim sel As Selection
    Dim please As String
    Dim s As String
    Dim mi As Outlook.mailItem
    Dim TransportMessageHeadersSchema As String

    ' https://social.msdn.microsoft.com/Forums/vstudio/en-US/e9342b09-02ba-441f-a824-5186bd9835a9/mailitemread-event?forum=outlookdev
    TransportMessageHeadersSchema = "http://schemas.microsoft.com/mapi/proptag/0x007D001E"

    Set exp = Application.ActiveExplorer

    If exp Is Nothing Then
      MsgBox "No Explorer!"
    Else
      Set sel = exp.Selection

      please = " Please select one Mail!"
      If sel Is Nothing Then
        MsgBox "No Selection!" & please
      ElseIf sel.count > 1 Then
        MsgBox "Multiple selection!" & please
      ElseIf sel.count < 1 Then
        MsgBox "No Selection!" & please
      ElseIf sel.item(1).Class <> olMail Then
        MsgBox "No Mail selected!" & please
      Else
        Set mi = sel.item(1)

        If mi Is Nothing Then
          MsgBox "No mail selected!"
        Else
            s = mi.PropertyAccessor.GetProperty(TransportMessageHeadersSchema)

            MsgBox s, vbInformation, "Mail Header"
        End If
      End If
    End If
End Sub

Uma macro semelhante é descrita aqui . Em vez de abrir um MsgBox , o cabeçalho do e-mail pode ser mostrado como e-mail ou como arquivo de texto via editor de texto ou navegador da web.