Como faço para me livrar do OneDrive completamente?

Question

Primeiro, tentei o link que está usando o gpedit.msc Em segundo lugar, eu tentei link que está usando o SysWOW64 \ OneDriveSetup.exe para desinstalar e excluir algumas das chaves de registro que sobraram .

Eu reiniciei.

E ainda toda vez que eu abro o explorador, eu tenho esse grande p.o.s. banner que me faz odiar mesmo usando janelas.

Como posso me livrar disso e do OneDrive completamente?

    

Answer 1

use este script para remover o Onedrive completamente:

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

Acho que você perdeu a última etapa para remover as 4 entradas do registro.

Ok, você pode usar um Insider Build e o que você vê são Dicas / Anúncios no Explorer . Para desativá-lo, abra as opções do Explorer e desmarque a entrada "Mostrar notificações do provedor de sincronização"