Como executar arquivos .cmd como Admin por padrão

Question

Eu criei um arquivo .cmd simples:

sc stop audiosrv
sc start audiosrv

mas eu tenho que clicar com o botão direito e "Executar como administrador" como posso definir este arquivo para ser executado como administrador por padrão após o clique duplo à esquerda?

    

Answer 1

Chame-o com PSEXEC -h

Isso vai funcionar. Além disso, você pode desabilitar completamente o UAC.

    

Answer 2

Coloque isso antes do início do seu script:

@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
set params = %*:"=""
echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"
exit /B

:gotAdmin
pushd "%CD%"
CD /D "%~dp0"