Convertendo um DWG / DXF para CSV ou Excel

Question

Estou usando o ZWcad e preciso obter as coordenadas de centenas de blocos em uma planilha de excel ou arquivo .CSV para que eu possa importar isso para o hardware do GPS. Eu sei que existem muitas ferramentas para o autocad, eu provavelmente posso até mesmo escrever uma, mas na medida em que o ZWcad vai, eu pareço estar sem opções.

No entanto, o ZWcad também salva em DWG e exporta para todas as outras extensões cad conhecidas. Então eu queria saber se eu iria salvar os blocos que eu preciso para exportar para um determinado arquivo, pode haver uma ferramenta / programa para converter isso diretamente em .CSV.

    

Answer 1

Abaixo está um programa AutoLISP simples que demonstra como extrair as coordenadas do ponto de inserção do WCS para uma seleção de referências de bloco a um arquivo CSV delimitado por vírgulas.

(defun c:blk2csv ( / e f i p s )
    (if (and (setq s (ssget '((0 . "INSERT"))))
             (setq f (getfiled "" "" "csv" 1))
             (setq f (open f "w"))
        )
        (progn
            (repeat (setq i (sslength s))
                (setq i (1- i)
                      e (ssname s i)
                      p (trans (cdr (assoc 10 (entget e))) e 0)
                )
                (write-line (apply 'strcat (mapcar 'strcat (mapcar 'rtos p) '("," "," ""))) f)
            )
            (close f)
        )
    )
    (princ)
)