Resposta automática para o Notes Client 7.0

Question

Estou usando um cliente de notas (v 7.0). Eu criei uma conta de email com e-mail id [email protected] neste cliente (obviamente no servidor domino também). Quero responder automaticamente ao e-mail que é enviado para [email protected] com a mesma linha de assunto que deve ser anexada com "; SUCCESS" no final da linha de assunto.

    

Answer 1

Ok, você precisa de um agente de usuário e privilégios para criá-lo localmente, já que quase certamente não será permitido criá-lo na cópia do servidor do banco de dados de correio (a menos que os administradores do Domino sejam um bando de palhaços). Isso exigirá que o Domino Designer seja instalado em seu cliente, não apenas no Notes.

Você então configura o agente para ser executado em uma programação (digamos, 5 minutos). e depois codificar alguns LotusScript para processar os documentos relevantes que foram adicionados. Eu nunca tive sucesso com meus scripts para executar corretamente no evento "depois que o novo email chegou", mas você pode ter mais sorte: -).

Os scripts que fiz foram simples o suficiente para caber na função Initialize. Por exemplo, o seguinte colocará todas as mensagens na caixa de entrada com "qwertyuiop" no cabeçalho do assunto, na pasta de lixo eletrônico.

Sub Initialize
    Dim s As New notessession
    Dim db As notesdatabase
    Dim view As NotesView
    Dim doc As NotesDocument

    Set db = s.CurrentDatabase
    Set view = db.GetView("($InBox)")
    If Not view Is Nothing Then
        Set doc = view.GetFirstDocument
        While Not doc Is Nothing
            If Instr(doc.GetFirstItem("subject").Text, "qwertyuiop")  Then
                Call doc.RemoveFromFolder( "($InBox)")
                Call doc.PutInFolder( "junk")
            End If
            Set doc = view.GetNextDocument(doc)
        Wend
    End If
End Sub

Os campos de seu interesse são subject , inetfrom e inetsendto (pelo menos no meu e-mail DB). Você pode verificar isso clicando com o botão direito do mouse em um dos e-mails, selecionando "Propriedades do documento" e selecionando a segunda guia (o triângulo) que lista todos os campos do documento.

Criar um email de resposta deve ser uma simples questão de criar um novo documento no banco de dados de correio e chamar " newdoc.send(true,true) ". Eu nunca tive que fazer isso antes, mas eu bati o código de exemplo a seguir juntos e parece funcionar (mas a correção de bugs é de sua responsabilidade, não minha: -).

Sub Initialize
    Dim s As New notessession
    Dim db As notesdatabase
    Dim view As NotesView
    Dim doc As NotesDocument
    Dim olddoc As NotesDocument
    Dim subj As String
    Dim newdoc As NotesDocument

    Set db = s.CurrentDatabase
    Set view = db.GetView("($InBox)")
    If Not view Is Nothing Then
        Set doc = view.GetFirstDocument
        While Not doc Is Nothing
            Set olddoc = doc
            Set doc = view.GetNextDocument(doc)
            subj = olddoc.GetFirstItem("subject").Text
            If Instr(subj, "qwertyuiop") > 0  And Right(subj,8) <> " SUCCESS" Then
                Set newdoc = New NotesDocument(db)
                newdoc.SendTo = olddoc.GetFirstItem("inetfrom").Text
                newdoc.subject = subj & " SUCCESS"
                newdoc.form = "Memo"
                Call newdoc.send(True,True)
                Call olddoc.RemoveFromFolder( "($InBox)")
                Call olddoc.PutInFolder( "junk")
            End If
        Wend
    End If
End Sub

    

Answer 2

Eu não sei o suficiente sobre o Notes para saber se é peculiar à configuração da IBM ou se é um problema genérico, mas o agente 'Out of Office' que recebemos envia mensagens do OOO para listas de discussão, o que é anti -social. Conseqüentemente, eu o configurei para não responder às pessoas que enviam de endereços de e-mail externos (Internet) - apenas para endereços de e-mail internos (no estilo do Notes).

Você pode identificar funcionários da IBM em listas de discussão - eles são aqueles que respondem com mensagens do OOO. (Existem outros também, mas ...)