Obtendo o caminho Unix de vários arquivos / pastas no serviço Automator

Question

Eu quero obter o caminho de (vários) arquivos (s, pastas) no serviço Automator, selecionando-os no Finder e, em seguida, usá-los no comando shell.

Eu já tenho algo assim:

Inicie o AppleScript:

on run {input, parameters}
tell application "Terminal"
    activate
    do script with command "clamscan --bell -i " & POSIX path of input
end tell

fim da corrida

Isso funciona, mas apenas para um arquivo ou pasta e não converte /path/file with spaces em /path/file\ with\ spaces .

Então, como consertar isso?

    

Answer 1

Como você está fazendo isso no Automator , com um Executar o AppleScript acton , isso fará o que você precisa:

on run {input, parameters}

    set theItemsToScanList to {}
    repeat with i from 1 to count input
        set end of theItemsToScanList to quoted form of (POSIX path of (item i of input as string)) & space
    end repeat

    tell application "Terminal"
        activate
        do script with command "clamscan --bell -i " & theItemsToScanList
    end tell

end run

Não há necessidade de complicar as coisas e passar pela ladainha mostrada na outra resposta!

Ou se você optar por fazê-lo em um script / aplicativo AppleScript , isso fará o que você precisa:

set theseItems to application "Finder"'s selection

set theItemsToScanList to {}
repeat with i from 1 to count theseItems
    set end of theItemsToScanList to quoted form of (POSIX path of (item i of theseItems as string)) & space
end repeat

tell application "Terminal"
    activate
    do script with command "clamscan --bell -i " & theItemsToScanList
end tell

Nota: O exemplo AppleScript código acima é apenas isso, e não inclui nenhum tratamento de erros como pode ser apropriado / necessário / desejado, o ônus é sobre o usuário adicionar qualquer tratamento de erros para qualquer código de exemplo apresentado e ou código escrito pelo próprio.

    

Answer 2

Isso funciona para mim usando a última versão do Sierra

property posixPathofSelectedFinderItems : {}
property QposixPathofSelectedFinderItems : {}
-- stores the selected files in the active finder window
-- in the variable "these_items"
tell application "Finder"
    set these_items to the selection
end tell

-- returns the Posix Path of each of those files and 
-- stores all of that info in the "posixPathofSelectedFinderItems"
-- as a list
repeat with i from 1 to the count of these_items
    set this_item to (item i of these_items) as alias
    set this_info to POSIX path of this_item
    set end of posixPathofSelectedFinderItems to this_info
end repeat

repeat with i from 1 to number of items in posixPathofSelectedFinderItems
    set this_item to item i of posixPathofSelectedFinderItems
    set this_item to quoted form of this_item
    set end of QposixPathofSelectedFinderItems to (this_item & " ")
end repeat
tell application "Terminal"
    activate
    do script with command "clamscan --bell -i " & items of QposixPathofSelectedFinderItems
end tell
set posixPathofSelectedFinderItems to {}
set QposixPathofSelectedFinderItems to {}