'IF "Fórmula no Excel com condições adicionais

Question

Estou trabalhando em um modelo que calcula o custo / preço de um gabinete e estou preso em um certo ponto. Existem 3 tipos de gabinetes e há uma condição em que um custo específico é aplicado ao tipo de gabinete com base em seu tamanho (Altura, Largura e Profundidade)

A condição é: Para ARQUIVOS ALTO - 84 Polegadas ALTA, 24 Polegadas DEEP, O custo é de US $ 90 POR FT LINEAR.

1. adicione $ 1,00 em custo para cada polegada adicional em altura
2. adicione $ 1,00 em custo por cada polegada adicional em profundidade ou subtraia $ 1,00 por cada polegada abaixo de 24 polegadas de profundidade

Para ARMÁRIOS DE PAREDE- 13 Polegadas DEEP e 30 polegadas OU MENOS EM ALTURA, o custo é de US $ 30 POR FT LINEAR.

1. adicione $ .50 por cada polegada adicional em altura
2. adicione $ .50 por cada polegada adicional em profundidade

Para ARMÁRIOS DE BASE - 24 Polegadas DEEP e 34 ½ Polegadas ALTA, O custo é de US $ 40 POR FT LINEAR.

1. adicione $ .50 por cada polegada adicional em profundidade
2. subtrair $ .50 para cada polegada abaixo de 24 polegadas em profundidade
3. adicione ou subtraia $ .50 para cada polegada acima ou abaixo de 34 ½ polegada de altura

Agora eu tenho uma fórmula de IF para calcular o custo padrão de acordo com o tamanho padrão dos três tipos de gabinete (veja abaixo e arquivo anexado). Mas eu quero alterar / modificar a fórmula para mostrar a mudança no custo quando o tamanho muda.

=IF($C$5="Base Cabinet",($O$3*$C$6*$F$6),IF($C$5="Wall Cabinet",($O$4*$C$6*$F$6),IF($C$5="Tall Cabinet",($O$5*$C$6*$F$6),"Type not listed")))

Assim, por exemplo, com a fórmula acima, se eu selecionar um Gabinete Base, o custo mostrará US $ 80, mas o tamanho não é considerado aqui a partir de agora. Digamos que se o tamanho do Gabinete for 34,5 (Alta) x 24 (Profunda), então o valor que estou recebendo (US $ 80) está correto, mas se o tamanho aumentar ou diminuir, o valor deverá mudar. Então é isso que eu preciso de ajuda.

O arquivo de exemplo está no local abaixo: link

Screenshot:

    

Answer 1

Com base no texto de sua pergunta, o que pode estar complicando o problema para você é pensar nos ajustes que você deseja adicionar como "condições" adicionais (se uma dimensão de gabinete variar do padrão e, em seguida, ajustar). Na verdade, não são condições, são apenas cálculos que podem ser incorporados à sua fórmula. Para dimensões padrão, os ajustes são iguais a zero.

Você já tem o framework lá. Tudo o que você precisa fazer é adicionar os cálculos adicionais. Estou assumindo que seus ajustes de custo são para o custo por LF, não líquido para o preço do gabinete.

Neste momento, você tem um custo "base" por LF na coluna O, ao qual deseja adicionar ajustes. Você descreve dois tipos de ajustes:

• "adicionar ou subtrair", que estaria na forma de ajuste (real - padrão) *
• "adicionar se maior", que seria na forma de (MAX (real, padrão) - padrão) * ajuste

Se houver alguma chance de que o valor de ajuste possa mudar com o tempo, é recomendável armazená-los em uma célula, digamos na coluna P (ou P e Q), associados ao tipo de gabinete, e se referir à célula na fórmula, em vez de codificar o valor. Isso poupará ter que modificar suas fórmulas mais tarde. Para este exemplo, no entanto, incluirei apenas o valor na fórmula. Então, adicionando os ajustes ficaria assim:

=IF($C$5="Base Cabinet",(($O$3+($F$3-34.5)*0.5+($F$5-24)*0.5)*$C$6*$F$6),
 IF($C$5="Wall Cabinet",(($O$4+(MAX($F$3,30)-30)*0.5+(MAX($F$5,13)-13)*0.5)*$C$6*$F$6),
 IF($C$5="Tall Cabinet",(($O$5+($F$3-84)*1+(MAX($F$5,24)-24)*1)*$C$6*$F$6),"Type not listed")))

Note que divido a fórmula em várias linhas para facilitar a leitura. Se você deseja copiar e colar, exclua as retornos de carro e os espaços extras primeiro.